/*

	camproc.h

	    カメラワークに関する関数をまとめたファイル



	2000/09/01 H.Yoshiike

	$Id: camproc.h,v 1.15 2002/06/25 08:25:54 usr03682 Exp $





*/



// ファイルが二重呼びされたときの対処

#ifndef d:CAMPROC_H

#define CAMPROC_H	1



//-----------------------------------------------------------------------------------------------

// カメラのＯＦＦ(シナリオカメラなどでカメラを強制的にＯＦＦするときに使用)

//-----------------------------------------------------------------------------------------------

proc カメラＯＦＦ $:カメラ名 {

	#if d:DEBUG_PRINT

		print 'camera_off'

	#endif



	chara delay カメラＯＦＦ \

		-time 2 \

		-arg $:カメラ名 \

		-exec {

			chara カメラ設定 $1 -s -1

		}

}



proc タイマー付きカメラＯＦＦ $:カメラ名 $:タイマー {

	chara delay カメラＯＦＦディレイ \

		-time $:タイマー \

		-arg  $:カメラ名 \

		-exec {

			chara カメラ設定 $1 -s -1

		}

}



//-----------------------------------------------------------------------------------------------

// スムーズカメラ関係

//-----------------------------------------------------------------------------------------------

// プレーヤーの位置判定機能付きのスムーズカメラ(範囲指定外は境界の値を維持するタイプ)

//-----------------------------------------------------------------------------------

// 昇順タイプ

proc CS_スムーズカメラ昇順 $:CS_プレイヤー位置 $:CS_プレイヤー位置開始 $:CS_プレイヤー位置終了 $:CS_補完開始 $:CS_補完終了 {

// 	($:CS_プレイヤー位置開始 < $:CS_プレイヤー位置終了)の場合はこっち

	if ($:CS_プレイヤー位置 < $:CS_プレイヤー位置開始) {

		eval( $i:CS_結果１= $:CS_補完開始);

	} else if ($:CS_プレイヤー位置 > $:CS_プレイヤー位置終了) {

		eval( $i:CS_結果１= $:CS_補完終了);

	} else {

		eval( $i:CS_割合 = ( $:CS_プレイヤー位置 - $:CS_プレイヤー位置開始 ) * 10000  / ($:CS_プレイヤー位置終了 - $:CS_プレイヤー位置開始 ) );

		eval( $i:CS_結果１ = $:CS_補完開始 + ( $:CS_補完終了 - $:CS_補完開始 ) * $i:CS_割合 / 10000 );

	}

}



// 降順タイプ

proc CS_スムーズカメラ降順 $:CS_プレイヤー位置 $:CS_プレイヤー位置開始 $:CS_プレイヤー位置終了 $:CS_補完開始 $:CS_補完終了 {

// 	($:CS_プレイヤー位置開始 > $:CS_プレイヤー位置終了)の場合はこっち

	if ($:CS_プレイヤー位置 > $:CS_プレイヤー位置開始) {

		eval( $i:CS_結果１= $:CS_補完開始);

	} else if ($:CS_プレイヤー位置 < $:CS_プレイヤー位置終了) {

		eval( $i:CS_結果１= $:CS_補完終了);

	} else {

		eval( $i:CS_割合 = ( $:CS_プレイヤー位置 - $:CS_プレイヤー位置開始 ) * 10000  / ($:CS_プレイヤー位置終了 - $:CS_プレイヤー位置開始 ) );

		eval( $i:CS_結果１ = $:CS_補完開始 + ( $:CS_補完終了 - $:CS_補完開始 ) * $i:CS_割合 / 10000 );

	}

}





// プレーヤーの位置判定機能付きのスムーズカメラ(範囲指定外までトラップがあるとバグの可能性があるので注意)

//-----------------------------------------------------------------------------------

// 戻り値１つ

proc CS_スムーズカメラ  $:CS_プレイヤー位置 $:CS_プレイヤー位置開始 $:CS_プレイヤー位置終了 $:CS_補完開始 $:CS_補完終了 {

	eval( $i:CS_割合 = ( $:CS_プレイヤー位置 - $:CS_プレイヤー位置開始 ) * 100  / ($:CS_プレイヤー位置終了 - $:CS_プレイヤー位置開始 ) );

	eval( $i:CS_結果１ = $:CS_補完開始 + ( $:CS_補完終了 - $:CS_補完開始 ) * $i:CS_割合 / 100 );

}



// 戻り値２つ

proc CS_スムーズカメラ２  $:CS_プレイヤー位置 $:CS_プレイヤー位置開始 $:CS_プレイヤー位置終了 $:CS_補完開始 $:CS_補完終了 $:CS_補完開始２ $:CS_補完終了２ {

	eval( $i:CS_割合 = ( $:CS_プレイヤー位置 - $:CS_プレイヤー位置開始 ) * 100  / ($:CS_プレイヤー位置終了 - $:CS_プレイヤー位置開始 ) );

	eval( $i:CS_結果１ = $:CS_補完開始 + ( $:CS_補完終了 - $:CS_補完開始 ) * $i:CS_割合 / 100 );

	eval( $i:CS_結果２ = $:CS_補完開始２ + ( $:CS_補完終了２ - $:CS_補完開始２ ) * $i:CS_割合 / 100 );

}



// 戻り値３つ

proc CS_スムーズカメラ３  $:CS_プレイヤー位置 $:CS_プレイヤー位置開始 $:CS_プレイヤー位置終了 $:CS_補完開始 $:CS_補完終了 $:CS_補完開始２ $:CS_補完終了２ $:CS_補完開始３ $:CS_補完終了３ {

	eval( $i:CS_割合 = ( $:CS_プレイヤー位置 - $:CS_プレイヤー位置開始 ) * 100  / ($:CS_プレイヤー位置終了 - $:CS_プレイヤー位置開始 ) );

	eval( $i:CS_結果１ = $:CS_補完開始 + ( $:CS_補完終了 - $:CS_補完開始 ) * $i:CS_割合 / 100 );

	eval( $i:CS_結果２ = $:CS_補完開始２ + ( $:CS_補完終了２ - $:CS_補完開始２ ) * $i:CS_割合 / 100 );

	eval( $i:CS_結果３ = $:CS_補完開始３ + ( $:CS_補完終了３ - $:CS_補完開始３ ) * $i:CS_割合 / 100 );

}



// 戻り値４つ

proc CS_スムーズカメラ４  $:CS_プレイヤー位置 $:CS_プレイヤー位置開始 $:CS_プレイヤー位置終了 $:CS_補完開始 $:CS_補完終了 $:CS_補完開始２ $:CS_補完終了２ $:CS_補完開始３ $:CS_補完終了３ $:CS_補完開始４ $:CS_補完終了４ {

	eval( $i:CS_割合 = ( $:CS_プレイヤー位置 - $:CS_プレイヤー位置開始 ) * 100  / ($:CS_プレイヤー位置終了 - $:CS_プレイヤー位置開始 ) );

	eval( $i:CS_結果１ = $:CS_補完開始 + ( $:CS_補完終了 - $:CS_補完開始 ) * $i:CS_割合 / 100 );

	eval( $i:CS_結果２ = $:CS_補完開始２ + ( $:CS_補完終了２ - $:CS_補完開始２ ) * $i:CS_割合 / 100 );

	eval( $i:CS_結果３ = $:CS_補完開始３ + ( $:CS_補完終了３ - $:CS_補完開始３ ) * $i:CS_割合 / 100 );

	eval( $i:CS_結果４ = $:CS_補完開始４ + ( $:CS_補完終了４ - $:CS_補完開始４ ) * $i:CS_割合 / 100 );

}



proc 全部補完カメラ $:比較対象 $:距離小 $:距離大 $:ＰＸ１ $:ＰＸ２ $:ＰＹ１ $:ＰＹ２ $:ＰＺ１ $:ＰＺ２ $:ＴＸ１ $:ＴＸ２ $:ＴＹ１ $:ＴＹ２ $:ＴＺ１ $:ＴＺ２{

	@CS_スムーズカメラ昇順 $:比較対象 $:距離小 $:距離大 $:ＰＸ１ $:ＰＸ２

		eval( $i:補完ＰＸ= $i:CS_結果１ )

	@CS_スムーズカメラ昇順 $:比較対象 $:距離小 $:距離大 $:ＰＹ１ $:ＰＹ２

		eval( $i:補完ＰＹ= $i:CS_結果１ )

	@CS_スムーズカメラ昇順 $:比較対象 $:距離小 $:距離大 $:ＰＺ１ $:ＰＺ２

		eval( $i:補完ＰＺ= $i:CS_結果１ )

	@CS_スムーズカメラ昇順 $:比較対象 $:距離小 $:距離大 $:ＴＸ１ $:ＴＸ２

		eval( $i:補完ＴＸ= $i:CS_結果１ )

	@CS_スムーズカメラ昇順 $:比較対象 $:距離小 $:距離大 $:ＴＹ１ $:ＴＹ２

		eval( $i:補完ＴＹ= $i:CS_結果１ )

	@CS_スムーズカメラ昇順 $:比較対象 $:距離小 $:距離大 $:ＴＺ１ $:ＴＺ２

		eval( $i:補完ＴＺ= $i:CS_結果１ )

}



//-----------------------------------------------------------------------------------------------

// パンカメラ関係

// 使用する際にはPAN_CAMERAをdefineする

//-----------------------------------------------------------------------------------------------

#ifdef d:PAN_CAMERA

	// パンカメラ設定

	// 「proc パンカメラプロック」で使用

	chara カメラ パンカメラ -c 0 -l 0 -p 0



	// パンカメラプロック

	proc パンカメラプロック \

		$:p_px_src $:p_py_src $:p_pz_src \

		$:p_tx_src $:p_ty_src $:p_tz_src \

		$:p_px_dst $:p_py_dst $:p_pz_dst \

		$:p_tx_dst $:p_ty_dst $:p_tz_dst \

		$:p_pc_補完画角 \

		$:p_pc_持続フレーム数 \

		$:p_パッドリリース／無敵ＯＮ \

	{

		// delay内で使用する各数値の、変数への代入

		eval($i:px_dst = $:p_px_dst)

		eval($i:py_dst = $:p_py_dst)

		eval($i:pz_dst = $:p_pz_dst)

		eval($i:tx_dst = $:p_tx_dst)

		eval($i:ty_dst = $:p_ty_dst)

		eval($i:tz_dst = $:p_tz_dst)

		eval($w:pc_補完画角 = $:p_pc_補完画角)

		eval($w:pc_持続フレーム数 = $:p_pc_持続フレーム数)



		// パッドリリース／無敵ＯＮ条件のセット

		eval($f:padrelease_invinsible_on = $:p_パッドリリース／無敵ＯＮ)



		// パッドリリース／無敵ＯＮ

		if($f:padrelease_invinsible_on == 1) {

			command パッド操作 -release

			command プレイヤー無敵セット

			chara delay ディレイ -time $:p_pc_持続フレーム数 -exec {

					command パッド操作 -cancel

					command プレイヤー無敵解除

			}

		}



		// アングルの移動。実際。

		// srcアングル

print 'srcアングル'

		chara カメラ設定 パンカメラ \

			-c 1 \

			-p $:p_px_src,$:p_py_src,$:p_pz_src \

			-t $:p_tx_src $:p_ty_src $:p_tz_src \

			-a $:p_pc_補完画角 \

			-i 0 0 0 0 \

			-s 1



#if 1

print 'dstアングル'

		// dstアングル

		chara カメラ設定 パンカメラ \

			-c 1 \

			-p $i:px_dst $i:py_dst $i:pz_dst \

			-t $i:tx_dst $i:ty_dst $i:tz_dst \

			-a $w:pc_補完画角 \

			-z d:CAMERA_INTERP_CAMERA \ // 補完カメラフラグを指定。

			-interp_time $w:pc_持続フレーム数 \ // 補完時間を指定

			-s 1



print 'dstアングル終了'

		// 終了

		chara delay ディレイ -time $w:pc_持続フレーム数 -exec {

			chara カメラ設定 パンカメラ -s -1

print 'パンカメラ終了'

		}



#else



print 'dstアングル'

		// dstアングル

		chara delay ディレイ -time 1 -exec {

			chara カメラ設定 パンカメラ \

				-c 1 \

				-p $i:px_dst $i:py_dst $i:pz_dst \

				-t $i:tx_dst $i:ty_dst $i:tz_dst \

				-a $w:pc_補完画角 \

				-i 4 0 $w:pc_持続フレーム数 0  \

				-s 1



print 'dstアングル終了'

			// 終了

			chara delay ディレイ -time $w:pc_持続フレーム数 -exec {

				chara カメラ設定 パンカメラ -s -1

print 'パンカメラ終了'

			}

		}

#endif



	}









//野尻使用

proc 加減速パンカメラ \

	$:p_px_src $:p_py_src $:p_pz_src \

	$:p_tx_src $:p_ty_src $:p_tz_src \

	$:p_px_dst $:p_py_dst $:p_pz_dst \

	$:p_tx_dst $:p_ty_dst $:p_tz_dst \

	$:p_pc_補完画角 \

	$:p_pc_持続フレーム数 \

	$:p_パッドリリース／無敵ＯＮ \

	{



		// パッドリリース／無敵ＯＮ条件のセット

		eval($f:padrelease_invinsible_on = $:p_パッドリリース／無敵ＯＮ)



		// パッドリリース／無敵ＯＮ

		if($f:padrelease_invinsible_on == 1) {

			command パッド操作 -release

			command プレイヤー無敵セット

			chara delay ディレイ -time $:p_pc_持続フレーム数 -exec {

					command パッド操作 -cancel

					command プレイヤー無敵解除

			}

		}



		eval($w:カウント = 0)

		eval($w:pc_持続フレーム数 = $:p_pc_持続フレーム数)



		eval($i:px_src = $:p_px_src)

		eval($i:py_src = $:p_py_src)

		eval($i:pz_src = $:p_pz_src)

		eval($i:tx_src = $:p_tx_src)

		eval($i:ty_src = $:p_ty_src)

		eval($i:tz_src = $:p_tz_src)



		eval($i:px_dst = $:p_px_dst)

		eval($i:py_dst = $:p_py_dst)

		eval($i:pz_dst = $:p_pz_dst)

		eval($i:tx_dst = $:p_tx_dst)

		eval($i:ty_dst = $:p_ty_dst)

		eval($i:tz_dst = $:p_tz_dst)



		@加減速パンカメラ計算



	}





proc 加減速パンカメラ計算{



	eval($w:パンカメラ角度 = ( ($w:カウント * 2048) / $w:pc_持続フレーム数) )

	eval($i:パンカメラ割合 =  4096 - `%cos $w:パンカメラ角度` )



	eval($i:ＰＸ１ = $i:px_src + (($i:px_dst - $i:px_src) * $i:パンカメラ割合 / 8192) )

	eval($i:ＰＹ１ = $i:py_src + (($i:py_dst - $i:py_src) * $i:パンカメラ割合 / 8192) )

	eval($i:ＰＺ１ = $i:pz_src + (($i:pz_dst - $i:pz_src) * $i:パンカメラ割合 / 8192) )



	eval($i:ＴＸ１ = $i:tx_src + (($i:tx_dst - $i:tx_src) * $i:パンカメラ割合 / 8192) )

	eval($i:ＴＹ１ = $i:ty_src + (($i:ty_dst - $i:ty_src) * $i:パンカメラ割合 / 8192) )

	eval($i:ＴＺ１ = $i:tz_src + (($i:tz_dst - $i:tz_src) * $i:パンカメラ割合 / 8192) )





	print $w:パンカメラ角度

	print $i:パンカメラ割合

	print $i:ＰＸ１ $i:ＰＹ１ $i:ＰＺ１





	if($w:カウント < $w:pc_持続フレーム数 ){

		eval($w:カウント = $w:カウント + 1)



		chara カメラ設定 パンカメラ \

			-c 1 \

			-p $i:ＰＸ１,$i:ＰＹ１,$i:ＰＺ１ \

			-t $i:ＴＸ１,$i:ＴＹ１,$i:ＴＺ１ \

			-a 1000 \

//			-a $w:pc_補完画角 \

			-i 0 0 0 0  \

			-s 1



		chara delay 加減速パンカメラディレイ \

			-time 1 \

			-exec{

				@加減速パンカメラ計算

			}



	}else{

		eval($w:カウント = 0)



		chara カメラ設定 パンカメラ \

			-s 0



	}



}













#endif





/* 旧バージョン

// パンカメラプロック

proc パンカメラプロック \

	$:px_src $:py_src $:pz_src \

	$:tx_src $:ty_src $:tz_src \

	$:px_dst $:py_dst $:pz_dst \

	$:tx_dst $:ty_dst $:tz_dst \

	$:補完画角 \

	$:持続フレーム数 \

	$:パッドリリース／無敵ＯＮ \

{

	// パッドリリース／無敵ＯＮ条件のセット

	eval($f:padrelease_invinsible_on = $:パッドリリース／無敵ＯＮ)



	// パッドリリース／無敵ＯＮ

	if($f:padrelease_invinsible_on == 1) {

		command パッド操作 -release

		command プレイヤー無敵セット

	}



	// 毎フレームのパン移動量

	eval($i:ＰＸ加算値 = ($:px_dst - $:px_src) / $:持続フレーム数)

	eval($i:ＰＹ加算値 = ($:py_dst - $:py_src) / $:持続フレーム数)

	eval($i:ＰＺ加算値 = ($:pz_dst - $:pz_src) / $:持続フレーム数)

	eval($i:ＴＸ加算値 = ($:tx_dst - $:tx_src) / $:持続フレーム数)

	eval($i:ＴＹ加算値 = ($:ty_dst - $:ty_src) / $:持続フレーム数)

	eval($i:ＴＺ加算値 = ($:tz_dst - $:tz_src) / $:持続フレーム数)



	// '補完'変数の初期値代入

	eval($i:補完ＰＸ = $:px_src)

	eval($i:補完ＰＹ = $:py_src)

	eval($i:補完ＰＺ = $:pz_src)

	eval($i:補完ＴＸ = $:tx_src)

	eval($i:補完ＴＹ = $:ty_src)

	eval($i:補完ＴＺ = $:tz_src)



	// 補完画角値代入

	eval($w:補完画角 = $:補完画角)



	// カメラのパン実行

	chara プロック連続実行 連続実行 \

		-exec {

			chara カメラ設定 パンカメラ \

				-c 1 \

				-p $i:補完ＰＸ,$i:補完ＰＹ,$i:補完ＰＺ \

				-t $i:補完ＴＸ,$i:補完ＴＹ,$i:補完ＴＺ \

				-a $w:補完画角 \

				-i 0 0 0 0  \

				-s 1



			eval($i:補完ＰＸ = $i:補完ＰＸ + $i:ＰＸ加算値)

			eval($i:補完ＰＹ = $i:補完ＰＹ + $i:ＰＹ加算値)

			eval($i:補完ＰＺ = $i:補完ＰＺ + $i:ＰＺ加算値)

			eval($i:補完ＴＸ = $i:補完ＴＸ + $i:ＴＸ加算値)

			eval($i:補完ＴＹ = $i:補完ＴＹ + $i:ＴＹ加算値)

			eval($i:補完ＴＺ = $i:補完ＴＺ + $i:ＴＺ加算値)

		} \

		-time $:持続フレーム数 \

		-end_exec {

			// 元の状態に戻す

			chara カメラ設定 パンカメラ -s 0

			if($f:padrelease_invinsible_on == 1) {

				command パッド操作 -cancel

				command プレイヤー無敵解除

			}

		}

}

*/











//-----------------------------------------------------------------------------------------------

// スライドカメラ関係(現在はchara カメラに機能が追加されたのでそちらを使用するとよい)

//-----------------------------------------------------------------------------------------------

/* CameraStander(CS)関数群 */

proc CS_左右スライドカメラ  $:CS_プレイヤーＸ位置 $:CS_ギャップ $:CS_補完時間 $:CS_前回カメラ位置Ｘ {

	if ( $f:CS_入るフラグ == 0 ) {

		eval( $f:CS_東西向いたフラグ = 0 ) ;

		eval( $i:CS_カメラ位置Ｘ = $:CS_プレイヤーＸ位置 );

		eval( $f:CS_入るフラグ = 1 ) ;

	} else {

		eval( $i:CS_カメラ位置Ｘ = $:CS_前回カメラ位置Ｘ );

	}

	if (( $w:プレイヤー方向 <= ( 1024 + 512 )) && ( $w:プレイヤー方向 >= ( 1024 - 512 ))) {

		if ( $f:CS_東西向いたフラグ == 0 ) {

			eval( $f:CS_東西向いたフラグ = 1 ) ;

			eval( $i:CS_最終カメラ補完Ｘ = $:CS_プレイヤーＸ位置 - $i:CS_カメラ位置Ｘ ) ;

			eval( $i:CS_補完時間カウンタ = 0 ) ;

			eval( $i:CS_最終前方補完Ｘ = $:CS_ギャップ) ;

		}

		eval( $i:CS_補完時間カウンタ = $i:CS_補完時間カウンタ + 1 ) ;

	} else if (( $w:プレイヤー方向 <= ( 3072 + 512 )) && ( $w:プレイヤー方向 >= ( 3072 - 512 ))) {

		if ( $f:CS_東西向いたフラグ == 0 ) {

			eval( $f:CS_東西向いたフラグ = 1 ) ;

			eval( $i:CS_最終カメラ補完Ｘ = $:CS_プレイヤーＸ位置 - $i:CS_カメラ位置Ｘ ) ;

			eval( $i:CS_補完時間カウンタ = 0 ) ;

			eval( $i:CS_最終前方補完Ｘ = -$:CS_ギャップ ) ;

		}

		eval( $i:CS_補完時間カウンタ = $i:CS_補完時間カウンタ + 1 ) ;

	} else {

		eval( $f:CS_東西向いたフラグ = 0 ) ;

	}

	if ( $i:CS_補完時間カウンタ >= $:CS_補完時間 ) {

		eval( $i:CS_補完時間カウンタ = $:CS_補完時間 ) ;

	}

	eval( $i:CS_結果１ = ( $:CS_プレイヤーＸ位置 - ( $i:CS_最終カメラ補完Ｘ * ($:CS_補完時間 - $i:CS_補完時間カウンタ) / $:CS_補完時間 ) + ( $i:CS_最終前方補完Ｘ  * $i:CS_補完時間カウンタ ) / $:CS_補完時間 )) ;

}

proc CS_左右スライドカメラ後処理 {

	eval( $f:CS_入るフラグ = 0 ) ;

}



proc CS_前後スライドカメラ  $:CS_プレイヤーＺ位置 $:CS_北向き距離 $:CS_南向き距離 $:CS_補完開始時間 $:CS_補完速度 $:CS_カメラＺ位置 {

	eval( $w:CS_プレイヤー方向 = $w:プレイヤー方向 & 4095 );



	if ( $w:CS_プレイヤー方向 >= 3072 ) {

		eval( $w:CS_プレイヤー方向 = $w:CS_プレイヤー方向 - 4096 );

	} else {

		eval( $w:CS_プレイヤー方向 = $w:CS_プレイヤー方向 );

	}



	if (( $w:CS_プレイヤー方向 <= ( 2048 + 512 )) && ( $w:CS_プレイヤー方向 >= ( 2048 - 512 ))) {

		eval( $i:CS_前後補完時間カウンタ = $i:CS_前後補完時間カウンタ + 1 ) ;

		if ( $i:CS_前後補完時間カウンタ > $:CS_補完開始時間 ) {

			eval( $i:CS_プレイヤー間距離 = $:CS_カメラＺ位置 - $:CS_プレイヤーＺ位置 );

			if ( $i:CS_プレイヤー間距離 <= $:CS_北向き距離 ) {

				eval( $i:CS_プレイヤー間距離 = $:CS_北向き距離 );

			} else {

				eval( $i:CS_プレイヤー間距離 = $i:CS_プレイヤー間距離 - $:CS_補完速度 );

			}

		}

	} else if (( $w:CS_プレイヤー方向 <= ( 0 + 512 )) && ( $w:CS_プレイヤー方向 >= ( 0 - 512 ))) {

		eval( $i:CS_前後補完時間カウンタ = $i:CS_前後補完時間カウンタ + 1 ) ;

		if ( $i:CS_前後補完時間カウンタ > $:CS_補完開始時間 ) {

			eval( $i:CS_プレイヤー間距離 = $:CS_カメラＺ位置 - $:CS_プレイヤーＺ位置 );

			if ( $i:CS_プレイヤー間距離 >= $:CS_南向き距離 ) {

				eval( $i:CS_プレイヤー間距離 = $:CS_南向き距離 );

			} else {

				eval( $i:CS_プレイヤー間距離 = $i:CS_プレイヤー間距離 + $:CS_補完速度 );

			}

		}

	} else {

		eval( $i:CS_前後補完時間カウンタ = 0 ) ;

		eval( $i:CS_プレイヤー間距離 = $:CS_カメラＺ位置 - $:CS_プレイヤーＺ位置 );

	}



	eval( $i:CS_結果１ = $:CS_プレイヤーＺ位置 + $i:CS_プレイヤー間距離);

}

proc CS_前後スライドカメラ後処理 {

	eval( $i:CS_前後補完時間カウンタ = 0 ) ;

}



#else



print 'camproc.h double include!!!!!!!!!!!!!!!!!!!!!!!!!!!!!'



#endif



