/*

	a24c_bomb.h

	    人質部屋（アナザーミッション用モード別設定ファイル）



	2002/01/30 S.Mukaide

	$Id: a24c_photo.h,v 1.22 2002/09/24 05:56:45 usr04249 Exp $





*/





//------------------------------------------------------------

// 各ミッション別で使用するdefine

//------------------------------------------------------------

#define	MISSION_PHOTO	1	// 爆弾解体用プロック起動用



#define		警備兵巡回ルート１		1

#define		警備兵巡回ルート１＿２	110

#define		警備兵巡回ルート２		83

#define		警備兵巡回ルート３		82

#define		警備兵巡回ルート４		81

#define		警備兵巡回ルート５		84

//#define		警備兵巡回ルート６		85

//#define		警備兵スタジオ待機		75

#define		警備兵スタジオ脱出		76		//	a24c.gclで必要

#define		警備兵増員連絡１		77

#define		警備兵増員連絡２		78

#define		警備兵増員連絡３		79

#define		警備兵増員連絡４		80

#define		攻撃兵階段上待機１		58		//	a24c.gclで必要

#define		攻撃兵階段上待機２		59		//	a24c.gclで必要

#define		攻撃兵階段上待機３		60		//	a24c.gclで必要

#define		攻撃兵階段上待機４		61		//	a24c.gclで必要

#define		攻撃兵スタジオ待機１	6		//	a24c.gclで必要

#define		攻撃兵スタジオ待機２	7		//	a24c.gclで必要

#define		攻撃兵スタジオ待機３	8		//	a24c.gclで必要

#define		攻撃兵スタジオ待機４	9		//	a24c.gclで必要

#define		ライデン取り囲み１		86		//	a24c.gclで必要

#define		ライデン取り囲み２		87		//	a24c.gclで必要

#define		ライデン取り囲み３		88		//	a24c.gclで必要

#define		ライデン取り囲み４		89		//	a24c.gclで必要



//#define		ライデ	0x03000000





#include "dcam_alt.h"





//------------------------------------------------------------

// a_mode.hで呼び出されるプロック

//------------------------------------------------------------

//------------------------------------------------------------

// chara マップの前に呼ばれるproc

//------------------------------------------------------------

proc 写真撮影ミッション用マップ定義前設定 {

	command セットＶＲステータス d:VR_PHOTOGRAPH

	@全ミッション共通システム設定 d:VR_GOAL_FREE

	@写真撮影ミッションＶＲウィンドウ設定

	command セットルートオフセット d:SCN:写真撮影

	@ＶＲクリア設定 p:load_alt_photo_a01a_s2 p:A_ＲＥＴＲＹプロック

}





//---------------------------------------------------

// chara マップ設定、常駐キャラ設定の後に呼ばれるproc

// ※ command マップ設定をしないと全マップに登録されます。

/* このステージで使用されるマップ名

人質部屋

*/

//---------------------------------------------------

proc 写真撮影ミッション用マップ定義後設定 {

	// 全マップ共通で使用する基本キャラの設定

	command マップ設定 人質部屋 -set {

		@写真撮影ミッション用サウンド設定	// データは最初に呼ぶ

		@写真撮影ミッション用ローカル変数初期化

		@写真撮影ミッション用変数設定		// ドアのスイッチなどの変数を設定

		//@写真撮影ミッション用コマンダー設定

		@写真撮影ミッション用ＢＧＭ設定		// プレイヤー→敵兵→BGMの順で呼ぶ

		//@写真撮影ミッション用アイテム設置

		//@写真撮影ミッション用人質コマンダー設定

		//@写真撮影ミッション用人質設定

		@写真撮影用プロック

	}

}







//------------------------------------------------------------

// クリアしたときの処理

//------------------------------------------------------------

proc 写真撮影ミッション用クリア時処理 {

	#if d:DEBUG_PRINT

	print 'clear'

	#endif

}







//------------------------------------------------------------

// サウンドに関する設定

//------------------------------------------------------------

proc 写真撮影ミッション用サウンド設定 {

	#if d:DEBUG_PRINT

		print 'sound_set-bomb_misson'

	#endif



	chara サウンドマネージャー ＳＤマネ \

		-pak 0



	//		ＳＥ設定

	@サウンド効果音設定

}



proc 写真撮影ミッション用ＢＧＭ設定 {

	#if d:DEBUG_PRINT

		print 'bgm_set-bomb_misson'

	#endif

/*

	//ここはゲームオーバーデモのために特殊

	if ($s:登場ポイント == 盗聴イベント){

	} else if ($s:登場ポイント == オセロット接近イベント) {

		chara ＢＧＭマネージャー ＢＧＭマネ

	} else {

		command セットサウンドコード -c d:SNG_PLAY_05

	}

*/

	chara ＢＧＭマネージャー ＢＧＭマネ



/*

	//服装によってＢＧＭ変化

	trap ca001 d:PLAYER \

		-mask ？ \

		-item d:アイテム:ゴル兵制服 \

		-exec {

			if ($3 == 入る) {

			#if d:DEBUG_PRINT

				print 'ゴル兵ＢＧＭにチェンジ！！！'

			#endif

				command セットサウンドコード -c d:SD_AUTO_FADER2

			} else {

			#if d:DEBUG_PRINT

				print '普通ＢＧＭにチェンジ！！！'

			#endif

				command セットサウンドコード -c d:SD_AUTO_FADER1

			}

		}

*/

}







//------------------------------------------------------------

// 変数に関する設定

//------------------------------------------------------------

proc 写真撮影ミッション用ローカル変数初期化 {



	@写真撮影用ローカル変数初期化プロック



	$$f:モーション再生中フラグ = 0;

	$$b:タイマー = 0;

	$$b:ゴル数 = 0;

}



proc 写真撮影ミッション用変数設定 {

	#if d:DEBUG_PRINT

		print 'stage_var_set-bomb_misson'

	#endif



	//------------------------------------------------------------

	// ドアに関する設定(0-開かない 1-開く)

	//------------------------------------------------------------

	eval ($$b:ドアフラグ[0] = d:DOOR_FLAG_CLOSE );	//	人質部屋ドア



	// 装備

	$w:アイテム数Ｒ[ d:アイテム:デジカメ ] = 1;

	command シナリオ前装備変更 -number d:アイテム:デジカメ



	$w:武器 = d:武器:素手

	$w:アイテム = d:アイテム:素手



}



proc 写真撮影ミッションＶＲウィンドウ設定 {

	#if d:DEBUG_PRINT

		print 'vr_window_set'

	#endif



	@ＶＲウィンドウ設定	\

			[VRMSG_J:ALT_PHT_a24c_SNA] [VRMSG_E:ALT_PHT_a24c_SNA] \	// 日、英

			[VRMSG_G:ALT_PHT_a24c_SNA] [VRMSG_F:ALT_PHT_a24c_SNA] \	// 独、仏

			[VRMSG_I:ALT_PHT_a24c_SNA] [VRMSG_S:ALT_PHT_a24c_SNA] \	// 伊、西

			[VRMSG_K:ALT_PHT_a24c_SNA] \							// 韓

			p:写真撮影ミッションステージ開始時処理					// 終了プロック





	// ＶＲウィンドウを表示する

	mesg ＶＲウィンドウ ＶＲウィンドウ君 開く



/*

	// スタート時とクリア時に使用するカットインカメラ

	chara カメラ カットインカメラ		-c 0 -l 0 -p  0



	// スタート時のカメラ(必要な場合)

	chara カメラ設定 カットインカメラ \

		-c 1 \

		-p 43,8528,-1398 -t -43,5745,-5427 \

		-r 394,2062,0 -f 4897 \

		-a 200 \

		-i 0 -1 0 0 \

		-s 1

*/

}



/*************************************************************************************/

// ステージ開始時処理

/*************************************************************************************/

proc 写真撮影ミッションステージ開始時処理 {

	#if d:DEBUG_PRINT

		print 'game_start!!!!!'

	#endif



	// プレイヤーやパッドの制御等を行う a_stdproc.hで定義

	@全ミッション共通ステージ開始時処理



/*

	// カメラワークスタート(必要な場合)

	// 全体図

	chara カメラ設定 カットインカメラ \

		-c 1 \

		-p -90,17878,2163 -t -90,12036,-1689 \

		-r 644,2048,0 -f 6997 \

		-a 200 \

		-i 4 4 d:START_CAMERA_CHANGE_TIME d:START_CAMERA_CHANGE_TIME \

		-s 1



	chara delay ディレイ \

		-time d:START_CAMERA_CHANGE_TIME \

		-exec {

			chara カメラ設定 カットインカメラ -s -1

		}

*/

}





//------------------------------------------------------------

// 敵兵に関する設定

//------------------------------------------------------------

proc 写真撮影ミッション用警備兵セット {

	#if d:DEBUG_PRINT

		print 'watcher_set-bomb_misson'

	#endif

	//	A_警備兵 $:名前 $:ルート $:ノード $:ステータス $:守備Ｘ $:守備Ｙ $:守備Ｚ $:守備マップ



	@A_警備兵 敵兵:01 d:警備兵巡回ルート１＿２ 0 \

	(d:ENE_STATUS_ENDLES_CHASE | d:ENE_STATUS_BIG_SNORE | \

	d:ENE_STATUS_REPORT|d:ENE_STATUS_TALK_SLEEP) \

	10250,-8500,-65000 人質部屋

#if 1

	@A_警備兵 敵兵:02 d:警備兵巡回ルート２ 0 \

	(d:ENE_STATUS_ENDLES_CHASE | d:ENE_STATUS_BIG_SNORE | \

	d:ENE_STATUS_REPORT|d:ENE_STATUS_TALK_SLEEP) \

	10250,-8500,-65000 人質部屋



	@A_警備兵 敵兵:03 d:警備兵巡回ルート３ 0 \

	(d:ENE_STATUS_ENDLES_CHASE | d:ENE_STATUS_BIG_SNORE | \

	d:ENE_STATUS_REPORT|d:ENE_STATUS_TALK_SLEEP) \

	10250,-8500,-65000 人質部屋



	@A_警備兵 敵兵:04 d:警備兵巡回ルート４ 0 \

	(d:ENE_STATUS_ENDLES_CHASE | d:ENE_STATUS_BIG_SNORE | \

	d:ENE_STATUS_REPORT|d:ENE_STATUS_TALK_SLEEP) \

	10250,-8500,-65000 人質部屋



	@A_警備兵 敵兵:05 d:警備兵巡回ルート５ 0 \

	(d:ENE_STATUS_ENDLES_CHASE | d:ENE_STATUS_BIG_SNORE | \

	d:ENE_STATUS_REPORT|d:ENE_STATUS_TALK_SLEEP) \

	10250,-8500,-65000 人質部屋

#endif

	//	とりあえず全員配置

	//	増員パターンにするときは@人質部屋増員連絡を使用して改良する

}



proc 写真撮影ミッション用攻撃兵セット {

	#if d:DEBUG_PRINT

		print 'attacker_set-bomb_misson'

	#endif

	//	A_攻撃兵 $:名前 $:ルート $:ステータス $:装備

	//	A_サポート攻撃兵 $:名前 $:ルート $:ステータス $:装備 $:サポートする敵兵名

}



proc 写真撮影ミッション用警備兵コマンダー {

	#if d:DEBUG_PRINT

		print 'wccomm_set-bomb_misson'

	#endif



	chara 警備コマンダー wccomm -e { 写真撮影ミッション用警備兵セット }

}



proc 写真撮影ミッション用攻撃兵コマンダー {

	#if d:DEBUG_PRINT

		print 'atcomm_set-bomb_misson'

	#endif



	chara 攻撃コマンダー atcomm \

		-e { 写真撮影ミッション用攻撃兵セット } \

		-wait (60*3) \			/*危険開始時の出動遅らせ時間*/

		-avoidwait (60*5) \		/*回避モードで始まる場合のみ有効*/

		-status 0x01

}



proc 写真撮影ミッション用コマンダー設定 {

	#if d:DEBUG_PRINT

		print 'commander_set-bomb_misson'

	#endif



	chara コマンダー 敵兵セット \

		-w 写真撮影ミッション用警備兵コマンダー \

		-r 4750,-8500,-70000 人質部屋 \

		-c 4750,-8500,-70000 人質部屋 \

		-v [ene_plant_voice:01] \

		-x [ghq_area_alert_voice:w24c] \

		-y [ghq_caution_voice:w24c] \

		-z $i:敵標準麻酔持続 \

		-o $i:敵標準気絶持続 \

		-b $w:敵標準再発生数 \

		-s (d:ENE_STAGE_CROWD_PEOPLE | d:ENE_STAGE_NO_WC_GOVER | d:ENE_STAGE_VR_ANOTHER) \

		-m $w:スタートアラートモード \

		-h $i:標準警戒時間 \			// 警戒時間

		-e	d:警備兵増員連絡１ 0 増員兵スタート前チェック \

			d:警備兵増員連絡２ 0 増員兵スタート前チェック \

			d:警備兵増員連絡３ 0 増員兵スタート前チェック \

			d:警備兵増員連絡４ 0 増員兵スタート前チェック \

			d:警備兵増員連絡１ 2 増員兵スタート \

			d:警備兵増員連絡２ 2 増員兵スタート \

			d:警備兵増員連絡３ 2 増員兵スタート \

			d:警備兵増員連絡４ 2 増員兵スタート \

		-f	d:警備兵増員連絡１			2 t:vc041000 t:vc041000_len \

			d:警備兵増員連絡２			2 t:vc041000 t:vc041000_len \

			d:警備兵増員連絡３			2 t:vc041000 t:vc041000_len \

			d:警備兵増員連絡４			2 t:vc041000 t:vc041000_len \

			d:警備兵巡回ルート１		1 t:vc043201 t:vc043201_len \

			d:警備兵巡回ルート１		4 t:vc043201 t:vc043201_len \

			d:警備兵巡回ルート１		8 t:vc043201 t:vc043201_len \

			d:警備兵巡回ルート１		10 t:vc043201 t:vc043201_len \

			d:警備兵巡回ルート１		13 t:vc043201 t:vc043201_len \

			d:警備兵巡回ルート１		18 t:vc043201 t:vc043201_len \

			d:警備兵巡回ルート１＿２	4 t:vc043201 t:vc043201_len \

			d:警備兵巡回ルート１＿２	12 t:vc043201 t:vc043201_len \

			d:警備兵巡回ルート１＿２	28 t:vc043201 t:vc043201_len \

			d:警備兵巡回ルート１＿２	38 t:vc043201 t:vc043201_len \

			d:警備兵巡回ルート１＿２	55 t:vc043201 t:vc043201_len



}







//------------------------------------------------------------

// 人質に関する設定

//------------------------------------------------------------

proc 写真撮影ミッション用人質死亡プロック {

	if(`%ゲームオーバーチェック` == 0 && $f:ロードチェックＯＮフラグ){

		@ゲームオーバー背景設定

		command ゲームオーバー処理開始 -exec {

			command メニュー設定 -menu off -gage off  -radar off -subwin off

			command ゲームオーバー処理終了

		}

	}

}



/*

proc NULL_PROC {



}

*/



proc 写真撮影ミッション用人質コマンダー設定 {



	chara 人質コマンダー 人質コマンダー \

		-e	写真撮影ミッション用人質死亡プロック \		//人質死亡

			NULL_PROC \		//発見された

			NULL_PROC \		//人質死亡

			NULL_PROC \		//敵兵死亡

			NULL_PROC \		//敵兵の無線が破壊された時に呼ばれる

			NULL_PROC \		//敵兵がホールドアップしたとき呼ばれる

			NULL_PROC \		//敵兵が気絶すると呼ばれる

			NULL_PROC \		//チャフ使用した

			NULL_PROC \		//警戒モードになった

			NULL_PROC \		//人質を殴った

		-v	t:vc121020 \//人質男性Ａ「（悲鳴、パニックになっている）」

			t:vc121021 \//人質男性Ｂ「（悲鳴、パニックになっている）」

			t:vc121024 \//人質男性Ａ「私はエイムズではない！」

			t:vc121025 \//人質男性Ｂ「私はエイムズではない！」

			t:vc121028 \//人質男性Ａ「違う！」

			t:vc121029 \//人質男性Ｂ「違う！」

			t:vc121032 \//人質男性Ａ「違うと言っただろう！」

			t:vc121033 \//人質男性Ｂ「違うと言っただろう！」

			t:vc121036 \//人質女性Ａ「（悲鳴、パニックになっている）」

			t:vc121037 \//人質女性Ｂ「（悲鳴、パニックになっている）」

			t:vc121038 \//人質女性Ａ「違う！」

			t:vc121039 \//人質女性Ｂ「違う！」

			t:vc121040 \//人質女性Ａ「近寄らないで！」

			t:vc121041 \//人質女性Ｂ「近寄らないで！」

			t:vc121042 \//人質女性Ａ「私じゃゃなくて他の人にして！」

			t:vc121043 \//人質女性Ｂ「私じゃなくて他の人にして！」

			t:vc121044 \//人質女性Ａ「やめて！触らないで！！」

			t:vc121045 \//人質女性Ｂ「やめて！触らないで！！」

			t:vc121046 \//人質女性Ｂ「私はジェニファーよ」

			t:vc121047 \//人質女性Ｂ「私はリンダ」

			t:vc121048 \//人質女性Ｂ「私はシンディーよ」

			t:vc121074 \//機械音「メールを送信しました」

		-m	1		//コマンダーがいないときの人質イベントの記述



}



proc 写真撮影ミッション用人質設定 {

	#if d:DEBUG_PRINT

		print 'hos_set'

		print '爆弾解体人質設定'

	#endif



	eval ($b:エイムズ番号 = 20);



	command foreach -argc 8 -repeat 27 \

		-data { \



		//左上の島

		{人質１		,-5750	,-60000	,0		,d:def_ハリソン			,d:HSTG_STATUS_NO_EIMS,hos_a	,0}\

		{人質２		,-4750	,-60000	,0		,d:def_カトチャン		,d:HSTG_STATUS_JITABATA2,hos_b	,1}\

		{人質３		,-3500	,-59000	,3072	,d:def_七三分け			,(d:HSTG_STATUS_SOPPO | d:HSTG_STATUS_NO_EIMS),hos_a	,2}\

		{人質４		,-3500	,-58000	,3072	,d:def_ヒゲオールバック	,d:HSTG_STATUS_JITABATA2,hos_b	,3}\

		{人質６		,-8000	,-58500	,1024	,d:def_ウィルスミス		,d:HSTG_STATUS_NO_EIMS2,hos_a	,4}\

		{人質７		,-8000	,-57500	,1024	,d:def_スナイプス		,d:HSTG_STATUS_JITABATA2,hos_b	,5}\

		{キャシー１	,-8000	,-56500	,1024	,d:def_キャシー			,d:HSTG_STATUS_PEE,hosf_d	,100}\





		//右上の島

		{人質１１	,2500	,-59000	,1024	,d:def_ヒゲカトチャン	,d:HSTG_STATUS_PEE,hos_c	,6}\

		{人質１２	,2500	,-58000	,1024	,d:def_ヒゲオールバック	,d:HSTG_STATUS_JITABATA2,hos_a	,7}\

		{ジェニファー,1000	,-57500	,0		,d:def_ラヴヒューイット	,(d:HSTG_STATUS_SOPPO | d:HSTG_STATUS_NOEIMS_OL),hosf_e	,100}\

		{人質１４	,2000	,-57500	,0		,d:def_スナイプス		,d:HSTG_STATUS_JITABATA2,hos_c	,8}\

		{キャシー２	,4500	,-58550	,3072	,d:def_キャシー			,d:HSTG_STATUS_JITABATA,hosf_d	,100}\

		{人質１７	,4500	,-56550	,3072	,d:def_ハリソン			,d:HSTG_STATUS_NO_EIMS,hos_a	,9}\





		//左下の島

		{人質１８	,-7500	,-48250	,3072	,d:def_ヒゲオールバック	,d:HSTG_STATUS_JITABATA2,hos_b	,10}\

		{人質１９	,-7250	,-48000	,0		,d:def_七三分け			,d:HSTG_STATUS_NO_EIMS,hos_b	,11}\

		{人質２０	,-5750	,-47500	,0		,d:def_ウィルスミス		,d:HSTG_STATUS_JITABATA2,hos_a	,12}\



		//デモで決まってる3人

		{人質２１	,-3500	,-51250	,3072	,d:def_ウィルスミス		,d:HSTG_STATUS_JITABATA2,hos_c	,13}\

		{キャシー３	,-4750	,-49250	,2048	,d:def_キャシー			,d:HSTG_STATUS_SOPPO,hosf_d	,100}\

		{人質２３	,-5250	,-53250	,0		,d:def_スナイプス		,d:HSTG_STATUS_JITABATA2,hos_a	,14}\





		//右下の島

		{人質２５	,2500	,-51000	,1024	,d:def_ヒゲハリソン		,d:HSTG_STATUS_PEE,hos_c	,15}\

		{人質２６	,2500	,-50000	,1024	,d:def_オールバック		,d:HSTG_STATUS_NO_EIMS2,hos_a	,16}\

		{人質２７	,2000	,-49500	,0		,d:def_ヒゲカトチャン	,(d:HSTG_STATUS_SOPPO | d:HSTG_STATUS_FOOT),hos_c	,17}\

		{キャシー４	,4500	,-52750	,3072	,d:def_キャシー			,d:HSTG_STATUS_JITABATA,hosf_d	,100}\

		{人質２９	,4500	,-51750	,3072	,d:def_ウィルスミス		,d:HSTG_STATUS_MAIL,hos_a	,18}\

		{人質３０	,4500	,-50500	,3072	,d:def_七三分け			,d:HSTG_STATUS_JITABATA2,hos_b	,19}\







		{エイムズ	,-3000	,-49550	,0		,0						,d:hos_ames,hos_a	,20}\



		{ジョニー	,-12750	,-62000	,3072	,d:def_七三分け			,d:HSTG_STATUS_SOPPO,hos_b	,21}\







	} \

	-exec { \



		if ($4 == 0) {

			eval($i:人質Ｘ座標 = $2)

			eval($i:人質Ｚ座標 = $3 + 200)



		} else if ($4 == 1024) {

			eval($i:人質Ｘ座標 = $2 + 200)

			eval($i:人質Ｚ座標 = $3)



		} else if ($4 == 2048) {

			eval($i:人質Ｘ座標 = $2)

			eval($i:人質Ｚ座標 = $3 - 200)



		} else if ($4 == 3072) {

			eval($i:人質Ｘ座標 = $2 - 200)

			eval($i:人質Ｚ座標 = $3)



		} else {

			eval($i:人質Ｘ座標 = $2)

			eval($i:人質Ｚ座標 = $3)

		}



		#if d:DEBUG_PRINT

		print 'エイムズは！！！！'$b:エイムズ番号

		#endif



		eval($i:人質ステータス = ($6 | d:HSTG_STATUS_LOD))

		if ($6 & d:HSTG_STATUS_MAIL) {

			eval($i:人質ステータス = (($i:人質ステータス & ~ d:HSTG_STATUS_MAIL) | d:HSTG_STATUS_JITABATA2))

		}



		if ($8 == $b:エイムズ番号) {

			eval($b:エイムズモデル = 0)

			eval($i:ローカル変数Ｉ２ = d:hos_ames)

		#if d:DEBUG_PRINT

			print 'エイムズ設置'

		#endif

			chara 人質達 エイムズ -p $i:人質Ｘ座標,-8500,$i:人質Ｚ座標 -d $4 -k $b:エイムズモデル -s $i:ローカル変数Ｉ２ -m $7

			//	エイムズランダムのときはこれでキャラクタを置き換える

			if($b:エイムズ番号 != 20){

				@人質モデル設定 $1 -3000 (-49550+200) 0 $5 $i:人質ステータス $7

			}

		}else if ($8 != 20) {

			@写真撮影ミッション用人質モデル設定 $1 $i:人質Ｘ座標 $i:人質Ｚ座標 $4 $5 $i:人質ステータス $7

		}



		if ($1 == ジョニー) {

		#if d:DEBUG_PRINT

			print '人質設置終わりぷりんぷりーん'

		#endif

		}

		@人質ガード透明壁 $i:人質Ｘ座標 $i:人質Ｚ座標 $4

	}

}



proc 写真撮影ミッション用人質モデル設定 $:名前 $:人質Ｘ座標 $:人質Ｚ座標 $:向き $:モデル $:ステータス $:モーション {

		chara 人質達 $1 -p $:人質Ｘ座標,-8500,$:人質Ｚ座標 -d $4 -k $5 -s $i:人質ステータス -m $7

		eval ($b:w24c_人質種類 = d:ノーマル)

}







//------------------------------------------------------------

// アイテムに関する設定

//------------------------------------------------------------

proc 写真撮影ミッション用アイテム取得時番号設定 $:ボックス名 {

}





//------------------------------------------------------------

// 写真撮影用カメラ

//------------------------------------------------------------

proc 写真撮影ミッション用人質部屋カメラ設定 {

		#if d:DEBUG_PRINT

			print 'w24c_camera_set'

		#endif



		// 全体

		trap ca001 d:PLAYER \

			-mask ＊ \

			-camera \

			-exec {

				@CS_スムーズカメラ昇順 $5 -6000 -5000 -10250 1000

				eval( $i:補完ＢＸ = $i:CS_結果１ );

				eval( $i:補完ＬＸ = $i:CS_結果１ );



				@CS_スムーズカメラ昇順 $5 -7000 -6000 470 150

				eval( $i:補完ＲＸ = $i:CS_結果１ );



				chara カメラ設定 サブカメラ１ \

					-c 0 \

					-b $i:補完ＢＸ,-1500 -62000 4500,d:CAM_MAX,-43000 \

					-l $i:補完ＬＸ,-6910,-66000 4500,d:CAM_MAX,/*-48000*/-48550 \

					-r $i:補完ＲＸ,2048,0 \

					-f 8000 \

					-a 200 \

					-i 1 -1 0 0 \

					-z d:CAMERA_NO_CUSHION \

					-s $3

			}



		//右側隅

		trap ca004 d:PLAYER \

			-mask ＊ \

			-camera \

			-exec {



				chara カメラ設定 サブカメラ２ \

					-c 1 \

					-p 5366,-4620,-46930 \

					-t $4,$5,$6 \

					-a 264 \

					-i 3 3 0 0 \

					-s $3



			}





		//南側壁はりつき

		trap ca008 d:PLAYER \

			-mask ？ \

			-camera \

			-state d:TRP_STATE_BEHINDCAMERA_ENABLE \

			-dir 2048,256 \

			-exec {



				chara カメラ設定 サブカメラ２ \

					-c 1 \

					-p $4,1540,-46470 \

					-t $4,-8460,-49270 \

					-a 200 \

					-i 0 0 0 0 \

					-s $3



			}



		//階段東側

		trap ca009 d:PLAYER \

			-mask ？ \

			-camera \

			-exec {



				chara カメラ設定 サブカメラ２ \

					-c 1 \

					-p 4428,-856,-57174 \

					-t 4472,-5215,-60796 \

					-a 179 \

					-i 3 3 0 0 \

					-s $3



			}





		//ステージ上

		trap ca006 d:PLAYER \

			-mask ＊ \

			-camera \

			-exec {



				@CS_スムーズカメラ昇順 $6 -58500 -50500 -8997 -8414

				eval( $i:補完ＰＸ = $i:CS_結果１ );



				@CS_スムーズカメラ昇順 $6 -58500 -50500 -263 -2820

				eval( $i:補完ＰＹ = $i:CS_結果１ );



				@CS_スムーズカメラ昇順 $6 -58500 -50500 -47736 -45014

				eval( $i:補完ＰＺ = $i:CS_結果１ );



				@CS_スムーズカメラ昇順 $6 -58500 -50500 -10337 -9772

				eval( $i:補完ＴＸ = $i:CS_結果１ );



				@CS_スムーズカメラ昇順 $6 -58500 -50500 -5986 -8680

				eval( $i:補完ＴＹ = $i:CS_結果１ );



				@CS_スムーズカメラ昇順 $6 -58500 -50500 -54581 -51734

				eval( $i:補完ＴＺ = $i:CS_結果１ );



				@CS_スムーズカメラ昇順 $6 -58500 -50500 245 200

				eval( $w:補完画角 = $i:CS_結果１ );





				chara カメラ設定 サブカメラ２ \

					-c 1 \

					-p $i:補完ＰＸ,$i:補完ＰＹ,$i:補完ＰＺ \

					-t $i:補完ＴＸ,$i:補完ＴＹ,$i:補完ＴＺ \

					-a $w:補完画角 \

					-i 3 3 0 0 \

					-s $3



			}





		//北側便所そば

		trap ca007 d:PLAYER \

			-mask ？ \

			-camera \

			-exec {



				chara カメラ設定 サブカメラ２ \

					-c 1 \

					-p -11682,-3885,-60783 \

					-t -11569,-13399,-64654 \

					-a 175 \

					-i 0 0 0 0 \

					-s $3



			}



		//階段付近

		trap ca003 d:PLAYER \

			-mask ＊ \

			-camera \

			-exec {



				//階段以北

				if($4 < 1000){





					@CS_スムーズカメラ昇順 $6 -66250 -64500 -56 558

					eval( $i:補完ＰＸ = $i:CS_結果１ );



					@CS_スムーズカメラ昇順 $6 -66250 -64500 -1994 597

					eval( $i:補完ＰＹ = $i:CS_結果１ );



					@CS_スムーズカメラ昇順 $6 -66250 -64500 -60546 -61783

					eval( $i:補完ＰＺ = $i:CS_結果１ );



					@CS_スムーズカメラ昇順 $6 -66250 -64500 1 303

					eval( $i:補完ＴＸ = $i:CS_結果１ );



					@CS_スムーズカメラ昇順 $6 -66250 -64500 -3910 -4605

					eval( $i:補完ＴＹ = $i:CS_結果１ );



					@CS_スムーズカメラ昇順 $6 -66250 -64500 -65877 -64047

					eval( $i:補完ＴＺ = $i:CS_結果１ );



					@CS_スムーズカメラ昇順 $6 -66250 -64500 188 130

					eval( $w:補完画角 = $i:CS_結果１ );





				//階段

				}else if($4 <= 5000){



					@CS_スムーズカメラ昇順 $4 1000 5000 558 2549

					eval( $i:補完ＰＸ = $i:CS_結果１ );



					@CS_スムーズカメラ昇順 $4 1000 5000 597 627

					eval( $i:補完ＰＹ = $i:CS_結果１ );



					@CS_スムーズカメラ昇順 $4 1000 5000 -61783 -60938

					eval( $i:補完ＰＺ = $i:CS_結果１ );



					@CS_スムーズカメラ昇順 $4 1000 5000 303 2339

					eval( $i:補完ＴＸ = $i:CS_結果１ );



					@CS_スムーズカメラ昇順 $4 1000 5000 -4605 -4562

					eval( $i:補完ＴＹ = $i:CS_結果１ );



					@CS_スムーズカメラ昇順 $4 1000 5000 -64047 -63210

					eval( $i:補完ＴＺ = $i:CS_結果１ );



					@CS_スムーズカメラ昇順 $4 1000 5000 130 200

					eval( $w:補完画角 = $i:CS_結果１ );



				}



				chara カメラ設定 サブカメラ２ \

					-c 1 \

					-p $i:補完ＰＸ,$i:補完ＰＹ,$i:補完ＰＺ \

					-t $i:補完ＴＸ,$i:補完ＴＹ,$i:補完ＴＺ \

					-a $w:補完画角 \

					-i 2 -1 0 0 \

					-s $3



			}







		//階段南側張り付き

		trap ca003 d:PLAYER \

			-mask ？ \

			-dir 2048,256 \

			-state d:TRP_STATE_BEHINDCAMERA_ENABLE \

			-camera \

			-exec {



				chara カメラ設定 モーションカメラ \

					-c 1 \

					-p 1559,2986,-61792 \

					-t 1557,-2673,-62105 \

					-a 197 \

					-i 1 -1 0 0 \

					-s $3



			}

	}



/*************************************************************************************/

// 写真撮影用プロック

/*************************************************************************************/



	proc 写真撮影用プロック {

		@大統領設置

		@ピーター設置

		@スコット設置

		@人質設置

		@股間押さえゴル兵設置



		@写真撮影セット

		#ifndef d:FIX_MODE

			@デバッグ用キーボード

		#endif

		// 撮影プロックは最後に

	}



/*************************************************************************************/

// 大統領設置

/*************************************************************************************/

	proc 大統領設置 {



		chara ルートデモ人形 大統領 \

			-route 2 0 \

			-kms jam_def_sh_mt \ //EVMを表示する場合はダミーKMSが必要

			-mar jam \

			-number 6 \

			-proc	大統領足ひっかけられた 7 \

					バック転開始 2 \

					大統領待機中 1



		chara プロック連続実行 大統領チェック -time -1 -exec {

			if( $w:アイテム == d:アイテム:デジカメ && !$$f:モーション再生中フラグ ) {

				if (`command カメラ視界チェック -camera 0x01 -pos -4600 -7500 -66200` ){

					$$b:タイマー = $$b:タイマー + 1;

					print 'タイマー'$$b:タイマー

					if( $$b:タイマー == 120 ) {

						$$b:タイマー = 0;

						$$f:モーション再生中フラグ = 1;

						mesg ルートデモ人形 大統領 アクション終了

					}

				} else {

					$$b:タイマー = 0;

				}

			} else {

				$$b:タイマー = 0;

			}

		}

	}



	proc 大統領足ひっかけられた {

		// 足出す

		mesg プットモーションモデル 人質 プロック判定付き再生 8

		mesg プットモーションモデル 人質 基本モーション変更 9

	}



	proc バック転開始 {

		// 足戻す

		mesg プットモーションモデル 人質 プロック判定付き再生 10

		mesg プットモーションモデル 人質 基本モーション変更 0

	}



	proc 大統領待機中 {

		$$f:モーション再生中フラグ = 0;

	}



/*************************************************************************************/

// ピーター設置

/*************************************************************************************/



	proc ピーター設置 {

		chara プットモーションモデル ピーター \

			-pos -11300 -8500 -66655 \

			-dir 1024 \

			-kms ptr_def_sh_mt \ 	//evmを表示する場合はダミーKMSが必要

			-mar ptr_w16a \

			-number 0 \ 			//省略時０

			-status	( 0x00 )



		// 杖

		chara 装備品Ｃ 杖 \

			-n ptr_stick_mt \

			-y ピーター \

			-z 6 \

			-x -60,-90,0 \

			-r 0,0,600 \

			-f 1

	}



/*************************************************************************************/

// スコット設置

/*************************************************************************************/



	proc スコット設置 {

		chara ルートデモ人形 スコット \

			-route 3 0 \

			-kms sna_def \

			-evm sco_standing \

			-mar a24c_photo_sco \

			-number 1 \

			-item sco_hat 12

	}



/*************************************************************************************/

// 人質設置

/*************************************************************************************/



	proc 人質設置 {

		chara プットモーションモデル 人質 \

			-pos -7750 -8500 -67250 \

			-dir 0 \

			-kms hos_malec_def \ 	//evmを表示する場合はダミーKMSが必要

			-mar hos_a \

			-number 0

	}



/*************************************************************************************/

// 人質設置

/*************************************************************************************/



	proc 股間押さえゴル兵設置 {

		trap no_crouch d:PLAYER \

			-mask いる \

			-exec {

				command プレイヤー死体歩き

			}



		// 台の上兵

		//@股間ゴルセット -2400 -7400 -58500 d:EAST (128) gbs_dead_for_subs

		chara プットオブジェ 股間ゴル兵 -m gbs_dead_for_subs -r 0 ( d:EAST + 128 ) 0 -p -2400 -7400 -58500 -l d:LT2_NAME



		@股間ゴルセット -3000 -8500 -54500 d:SOUTH (-512) gbs_dead2_for_subs

		@股間ゴルセット -2500 -8500 -49000 d:EAST (256) gbs_dead3_for_subs

		@股間ゴルセット 0 -8500 -52250 d:NORTH (-400) gbs_dead_for_subs

		@股間ゴルセット -1000 -8500 -46500 d:EAST (0) gbs_dead2_for_subs

		@股間ゴルセット 3000 -8500 -46500 d:WEST (0) gbs_dead_for_subs

		@股間ゴルセット -1000 -8500 -49000 d:SOUTH (-256) gbs_dead_for_subs

		@股間ゴルセット 1500 -8500 -49000 d:WEST (-256) gbs_dead2_for_subs

		@股間ゴルセット 4000 -8500 -49500 d:SOUTH (0) gbs_dead3_for_subs

		@股間ゴルセット 3000 -8500 -53500 d:SOUTH (0) gbs_dead_for_subs

		@股間ゴルセット -4000 -8500 -51000 d:SOUTH (-256) gbs_dead2_for_subs



		// 見張り台の上兵

		//@股間ゴルセット -5250 -4000 -48250 d:NORTH (0) gbs_dead2_for_subs

		chara プットオブジェ 股間ゴル兵 -m gbs_dead2_for_subs -r 0 ( d:NORTH + 128 ) 0 -p -5250 -4000 -48250 -l d:LT2_NAME



		@股間ライデンセット -6000 -8500 -57500 d:SOUTH (-256) gbs_dead_for_subs

	}



	proc 股間ゴルセット $:Ｘ $:Ｙ $:Ｚ $:方向 $:方向調整値 $:ファイル名 {



		chara プットオブジェ 股間ゴル兵 \

			-m $:ファイル名 \

			-r 0 ( $:方向 + $:方向調整値 ) 0 \

			-p $:Ｘ $:Ｙ $:Ｚ \

			-l d:LT2_NAME



		if( $:方向 == d:WEST || $:方向 == d:EAST ) {

			@SS_進入禁止エリア設定 進入禁止壁 -8500 250 ($:Ｘ-1000) ($:Ｚ+500) ($:Ｘ+1000) ($:Ｚ+500) 人質部屋

			@SS_進入禁止エリア設定 進入禁止壁 -8500 250 ($:Ｘ-1000) ($:Ｚ-500) ($:Ｘ+1000) ($:Ｚ-500) 人質部屋

			@SS_進入禁止エリア設定 進入禁止壁 -8500 250 ($:Ｘ-1000) ($:Ｚ-500) ($:Ｘ-1000) ($:Ｚ+500) 人質部屋

			@SS_進入禁止エリア設定 進入禁止壁 -8500 250 ($:Ｘ+1000) ($:Ｚ-500) ($:Ｘ+1000) ($:Ｚ+500) 人質部屋

		} else if( $:方向 == d:NORTH || $:方向 == d:SOUTH ) {

			@SS_進入禁止エリア設定 進入禁止壁 -8500 250 ($:Ｘ-500) ($:Ｚ+1000) ($:Ｘ+500) ($:Ｚ+1000) 人質部屋

			@SS_進入禁止エリア設定 進入禁止壁 -8500 250 ($:Ｘ-500) ($:Ｚ-1000) ($:Ｘ+500) ($:Ｚ-1000) 人質部屋

			@SS_進入禁止エリア設定 進入禁止壁 -8500 250 ($:Ｘ-500) ($:Ｚ-1000) ($:Ｘ-500) ($:Ｚ+1000) 人質部屋

			@SS_進入禁止エリア設定 進入禁止壁 -8500 250 ($:Ｘ+500) ($:Ｚ-1000) ($:Ｘ+500) ($:Ｚ+1000) 人質部屋

		}

	}



	proc 股間ライデンセット $:Ｘ $:Ｙ $:Ｚ $:方向 {

		chara プットオブジェ 股間ライデン \

			-m rai_dead_crotch_for_subs \

			-r 0 $:方向 0 \

			-p $:Ｘ $:Ｙ $:Ｚ \

			-l d:LT2_NAME \

			-f d:PUT_OBJ_CALC_LIGHT



		if( $:方向 == d:WEST || $:方向 == d:EAST ) {

			@SS_進入禁止エリア設定 進入禁止壁 -8500 250 ($:Ｘ-1000) ($:Ｚ+500) ($:Ｘ+1000) ($:Ｚ+500) 人質部屋

			@SS_進入禁止エリア設定 進入禁止壁 -8500 250 ($:Ｘ-1000) ($:Ｚ-500) ($:Ｘ+1000) ($:Ｚ-500) 人質部屋

			@SS_進入禁止エリア設定 進入禁止壁 -8500 250 ($:Ｘ-1000) ($:Ｚ-500) ($:Ｘ-1000) ($:Ｚ+500) 人質部屋

			@SS_進入禁止エリア設定 進入禁止壁 -8500 250 ($:Ｘ+1000) ($:Ｚ-500) ($:Ｘ+1000) ($:Ｚ+500) 人質部屋

		} else if( $:方向 == d:NORTH || $:方向 == d:SOUTH ) {

			@SS_進入禁止エリア設定 進入禁止壁 -8500 250 ($:Ｘ-500) ($:Ｚ+1000) ($:Ｘ+500) ($:Ｚ+1000) 人質部屋

			@SS_進入禁止エリア設定 進入禁止壁 -8500 250 ($:Ｘ-500) ($:Ｚ-1000) ($:Ｘ+500) ($:Ｚ-1000) 人質部屋

			@SS_進入禁止エリア設定 進入禁止壁 -8500 250 ($:Ｘ-500) ($:Ｚ-1000) ($:Ｘ-500) ($:Ｚ+1000) 人質部屋

			@SS_進入禁止エリア設定 進入禁止壁 -8500 250 ($:Ｘ+500) ($:Ｚ-1000) ($:Ｘ+500) ($:Ｚ+1000) 人質部屋

		}

	}



	// 進入禁止エリア設定

	proc SS_進入禁止エリア設定 $:壁の名前 $:床の高さ $:壁の高さ $:頂点１Ｘ $:頂点１Ｚ $:頂点２Ｘ $:頂点２Ｚ $:マップ名 {



		chara 透明壁 $:壁の名前 \

			-position  $:頂点１Ｘ $:床の高さ $:頂点１Ｚ $:壁の高さ \

				       $:頂点２Ｘ $:床の高さ $:頂点１Ｚ $:壁の高さ \

			-attribute (d:HZX_SEG_ATR_ALL & ~(d:HZX_SEG_NO_PLAYER)) \

			-map       $:マップ名

		chara 透明壁 $:壁の名前 \

			-position  $:頂点２Ｘ $:床の高さ $:頂点１Ｚ $:壁の高さ \

				       $:頂点２Ｘ $:床の高さ $:頂点２Ｚ $:壁の高さ \

			-attribute (d:HZX_SEG_ATR_ALL & ~(d:HZX_SEG_NO_PLAYER)) \

			-map       $:マップ名

		chara 透明壁 $:壁の名前 \

			-position  $:頂点２Ｘ $:床の高さ $:頂点２Ｚ $:壁の高さ \

				       $:頂点１Ｘ $:床の高さ $:頂点２Ｚ $:壁の高さ \

			-attribute (d:HZX_SEG_ATR_ALL & ~(d:HZX_SEG_NO_PLAYER)) \

			-map       $:マップ名

		chara 透明壁 $:壁の名前 \

			-position  $:頂点１Ｘ $:床の高さ $:頂点２Ｚ $:壁の高さ \

				       $:頂点１Ｘ $:床の高さ $:頂点１Ｚ $:壁の高さ \

			-attribute (d:HZX_SEG_ATR_ALL & ~(d:HZX_SEG_NO_PLAYER)) \

			-map       $:マップ名

	}



/*************************************************************************************/

// デバッグ用キーボード

/*************************************************************************************/

	proc デバッグ用キーボード {

		#include "usbkbd.h"

		chara USBキーボード実行 ＵＳＢキーボード \

		// 大統領

			-e d:KPD_1	{

				$$i:モーション番号 = $$i:モーション番号 + 1;

				print $$i:モーション番号

				mesg プットモーションモデル 人質 初期座標

				mesg プットモーションモデル 人質 終了判定 $$i:モーション番号

			} \

			-e d:KPD_2	{

				$$i:モーション番号 = $$i:モーション番号 - 1;

				print $$i:モーション番号

				mesg プットモーションモデル 人質 初期座標

				mesg プットモーションモデル 人質 終了判定 $$i:モーション番号

			} \

			-e d:KPD_4	{

				$$b:大統領フラグ = 0;

				mesg プットモーションモデル 大統領 プロック判定付き再生 36

			} \

			-e d:KPD_5	{

				$$b:大統領フラグ = 1;

				mesg プットモーションモデル 大統領 プロック判定付き再生 34

			} \

			-e d:KPD_6	{

				mesg プットモーションモデル 大統領 プロック判定付き再生 35

			}

	}



/*************************************************************************************/

// 写真撮影セット

/*************************************************************************************/

	proc 写真撮影セット {

		command カメラ撮影時プロック -proc 撮影時プロック



		command カメラチェックキャラワーク確保



		command カメラチェックキャラ登録 \

			-name 大統領 \

			-joint 12 \

			-far 1 \

			-proc 大統領写真判定

	}



	proc 大統領写真判定 {

		command ゲットデジカメ被写体情報 $$i:Ｘ画面位置 $$i:Ｙ画面位置 $$i:画面占有率



		#if d:DEBUG_PRINT

			@写真判定プリント文 $1

		#endif



		if( $1 == 1 ) {

			

			if( `@グラビアチェック範囲チェック 15 20 50` ) {

				$$b:撮影成功フラグ = 100;

			} else if( `@グラビアチェック範囲チェック 25 30 60` ) {

				$$b:撮影成功フラグ = 50;

			} else if( `@グラビアチェック範囲チェック 30 40 70` ) {

				$$b:撮影成功フラグ = 10;

			}

			

		}



	}



	proc 撮影時プロック {

		print '撮影成功フラグ'$$b:撮影成功フラグ



		if( $$b:撮影成功フラグ >= 70 ) {

			command ＶＲクリア＿星の数の設定 3

			command ＶＲクリア＿スコアの設定 ( d:PHOTO_STAR_SCORE * 3 )

		} else if( $$b:撮影成功フラグ >= 30 ) {

			command ＶＲクリア＿星の数の設定 2

			command ＶＲクリア＿スコアの設定 ( d:PHOTO_STAR_SCORE * 2 )

		} else if( $$b:撮影成功フラグ >= 10 ) {

			command ＶＲクリア＿星の数の設定 1

			command ＶＲクリア＿スコアの設定 ( d:PHOTO_STAR_SCORE * 1 )

		}



		#if 0

			command ＶＲポーズ中クリア

		#else

			if( $$b:撮影成功フラグ ) {

				command ＶＲポーズ中クリア

			} else {

				@ミッション共通ゲームオーバー処理

			}

		#endif



	}











