//=============================================================================

// polydemo_w43a.h

// ＡＧ・第一通路デモ用ステージ

// 2001/02/19 S.Yamashita

// $Id: polydemo_w43a.h,v 1.35 2001/09/04 09:15:06 usr03635 Exp $

//





/*

注意！　以下のevalは、stdch.hとdemo_stdch.h中の2Dレイアウトドライバ 

の二重呼びを回避するためのものです。各"polydemo_***.h" のこの位置、

include の前に必ずおくこと！！

*/

/* 絶対ここ！　場所も変えない！ */

eval($s:d_num = co_game_demo_stage)

/* 以上！ */



//=============================================================================

// include

//=============================================================================

#include "5sec_bfr_demo.h"

#include "demo_stdch.h"

#include "demo_vardef.h"



// ↓w43a.gcl で既にインクルード済み

//#include "p_force_cdc.ch"



#if d:PLANT_DEMO_ALL_SKIP

	#define		DEMO_SKIP_ENABLE 1

#else

	#define		DEMO_SKIP_ENABLE 0

#endif



#if d:MGS2_DEMO

#define DEMO_DOOR_CLOSE 0		// デモ：シナリオ置きドアの開閉設定。

								// 1 閉まってる   0 開いている

#endif



//###################################################################################

//								ストーリーフラグ & デモ再生

//###################################################################################



command マップ設定 丸通路 -set {

	// デモ環境かどうか。

	#if d:MGS2_DEMO

		// ドア開閉制御。上記のdefineで制御してください

		if(d:DEMO_DOOR_CLOSE == 0) {

			eval($s:d_num = P074_03_p02_0)

		} else {

			eval($s:d_num = hogehoge)

		}

chara デモアクトデバッグ demodebug  -i t:p073_02_p01 -d 'p073_02_p01' -l   \

			-p  null

	#else

		//	かつら等対応

		// ゲームＧＣＬと共用で入ってくる部分なので、== で条件を見る。

		if($w:p_story == d:ST:P073_02_P01通路Ａ２ポリゴンデモ１開始) {

			print'd:ST:P073_02_P01通路Ａ２ポリゴンデモ１開始'

			//eval($w:p_story = d:ST:P073_02_P01通路Ａ２ポリゴンデモ１開始)

			/* スネーク出現　ライデンは装備を取り戻す */

			// デモ特有の変数代入

			eval($s:d_num = P073_02_p01)

			// polydemo_**.h の最初のデモの時には必ず呼ぶこと。レーダー明示的にオフさせる。

			@デモではレーダー不要

//			@サウンドマネージャーセット

//			@サウンドマネージャー_mesg_1

			@デモモデル差し替え処理

			@デモ再生_P073_02_p01

		} else if(d:ST:P073_02_P01通路Ａ２ポリゴンデモ１終了 <= $w:p_story && \

							$w:p_story < d:ST:P073_03_R02通路Ａ３無線機デモ２開始) {

			eval($w:p_story = d:ST:P073_03_R02通路Ａ３無線機デモ２開始)

			print '$w:p_story = ST:P073_03_R02通路Ａ３無線機デモ２開始'

			/* スネーク体内通信　量産型レイの数は２５機！ */

			// デモ特有の変数代入

			eval($s:d_num = P073_03_r02)

			@rt_P073_03_R02通路Ａ３無線機デモ２

		} else if(d:ST:P073_03_R02通路Ａ３無線機デモ２終了 <= $w:p_story && \

							$w:p_story < d:ST:P073_04_P02通路Ａ４ポリゴンデモ２開始) {

			eval($w:p_story = d:ST:P073_04_P02通路Ａ４ポリゴンデモ２開始)

			print '$w:p_story = ST:P073_04_P02通路Ａ４ポリゴンデモ２開始'

			/* ライデン、スネークから刀を受け取る */



			/* デモの最中にブレードを背負っているのは変なので、解除する */

			/* 終了プロックの中で元に戻している */

			eval($w:武器弾数Ｒ[d:武器:ブレード] = 0)



			// デモ特有の変数代入

			eval($s:d_num = P073_04_p02)

			@デモモデル差し替え処理

			@デモ再生_P073_04_p02

		} else if($w:p_story == d:ST:P074_01_P01通路Ａ刀後１ポリゴンデモ１開始) {

			// ゲームＧＣＬと共用で入ってくる部分なので、== で条件を見る。

			print'd:ST:P074_01_P01通路Ａ刀後１ポリゴンデモ１開始'

			//eval($w:p_story = d:ST:P074_01_P01通路Ａ刀後１ポリゴンデモ１開始)

			/* 「無限バンダナだ」 */



			/* デモの最中にブレードを背負っているのは変なので、解除する */

			/* 終了プロックの中で元に戻している */

			eval($w:武器弾数Ｒ[d:武器:ブレード] = 0)



			// デモ特有の変数代入

			eval($s:d_num = P074_01_p01)

			// polydemo_**.h の最初のデモの時には必ず呼ぶこと。レーダー明示的にオフさせる。

			@デモではレーダー不要

			@デモモデル差し替え処理

			@デモ再生_P074_01_p01

		} else if(d:ST:P074_01_P01通路Ａ刀後１ポリゴンデモ１終了 <= $w:p_story && \

							$w:p_story < d:ST:P074_02_R01通路Ａ刀後２無線機デモ１開始) {

			eval($w:p_story = d:ST:P074_02_R01通路Ａ刀後２無線機デモ１開始)

			print '$w:p_story = ST:P074_02_R01通路Ａ刀後２無線機デモ１開始'

			/* スネーク体内通信　つまらん殺戮に手を貸すのはこれで最後にしろ */

			// デモ特有の変数代入

			eval($s:d_num = P074_02_r01)

			@rt_P074_02_R01通路Ａ刀後２無線機デモ１

		} else if(d:ST:P074_02_R01通路Ａ刀後２無線機デモ１終了 <= $w:p_story && \

							$w:p_story < d:ST:P074_03_P02通路Ａ刀後３ポリゴンデモ２開始) {

			eval($w:p_story = d:ST:P074_03_P02通路Ａ刀後３ポリゴンデモ２開始)

			print '$w:p_story = ST:P074_03_P02通路Ａ刀後３ポリゴンデモ２開始'

			/* 「次の世代に伝えるんだ」　といって通路を飛び出してゆくスネーク */

			// デモ特有の変数代入

			eval($s:d_num = P074_03_p02_0)

			@デモモデル差し替え処理

			@デモ再生_P074_03_p02

		} else {

			// デモの時以外は、以下を通過する。

			// このフラグが立っていると、親（ゲームの）GCLの方で必要なキャラが起動する。

			@ゲームステージへ戻る

		}

	#endif

	// デモ仕様のセット

	if($s:d_num != not_demo){

		// 共通して使用するもの

		chara デモキャンセルチェック デモキャンセル \

				-p demo_cancel

		// 無線ではシネマスクリーン起動しない

		if(($s:d_num != P073_03_r02) && ($s:d_num != P074_02_r01)){

			@シネマスクリーンセット

		}

		if ($s:d_num != P074_03_p02_0) {

			@ドア設定

		}

		@フォグ設定 // w43a.gcl で定義

		@空中文字設定 // w43a.gcl で定義

	}

} // < 「command マップ設定 第一通路」 の閉じカッコ



// 初期マップ表示

// ゲームgclの方で実施。

// command マップ表示 -show 丸通路









//=============================================================================

// プロシージャ

//=============================================================================

//###################################################################################

//									デモのみ仕様各種

//###################################################################################

// ダミープロック

proc null {}



// デモキャンセル

proc demo_cancel {

	command StreamStopAll

}



// リスタート

proc restart_proc {

	restart

}



// デモ終了時プロック

proc P073_02_p01終了 {

	@デモ終了時シネマスクリーンオフ

	mesg デモキャンセルチェック デモキャンセル kill



	print '$w:p_story = d:ST:P073_02_P01通路Ａ２ポリゴンデモ１終了'

	eval($w:p_story = d:ST:P073_02_P01通路Ａ２ポリゴンデモ１終了)



	chara delay ディレイ \

		-time 1 \ 

		-exec{

			restart

		}

}



proc P073_04_p02終了 {

	@デモ終了時シネマスクリーンオフ

	mesg デモキャンセルチェック デモキャンセル kill



	print '$w:p_story = d:ST:P073_04_P02通路Ａ４ポリゴンデモ２終了'

	eval($w:p_story = d:ST:P073_04_P02通路Ａ４ポリゴンデモ２終了)



	/* デモが始まる前にブレードを解除しているので元に戻す */

	eval($w:武器弾数Ｒ[d:武器:ブレード] = 1)

	eval ($w:プレイヤーフラグ = $w:プレイヤーフラグ | 0x0002 )

	eval ($w:武器 = d:武器:ブレード)



	chara delay ディレイ \

		-time 1 \ 

		-exec{

			// ゲームへ

			@ゲームステージへ戻る

			restart

		}

}



proc P074_01_p01終了 {

	@デモ終了時シネマスクリーンオフ

	mesg デモキャンセルチェック デモキャンセル kill



	print '$w:p_story = d:ST:P074_01_P01通路Ａ刀後１ポリゴンデモ１終了'

	eval($w:p_story = d:ST:P074_01_P01通路Ａ刀後１ポリゴンデモ１終了)



	/* デモが始まる前にブレードを解除しているので元に戻す */

	eval($w:武器弾数Ｒ[d:武器:ブレード] = 1)

	eval ($w:武器 = d:武器:素手)

	eval ($w:プレイヤーフラグ = $w:プレイヤーフラグ & ~d:PL_START_STATE_BLADE_OUT)



	chara delay ディレイ \

		-time 1 \ 

		-exec{

			restart

		}

}



proc P074_03_p02終了x {

	@デモ終了時シネマスクリーンオフ

	mesg デモキャンセルチェック デモキャンセル kill



	print '$w:p_story = d:ST:P074_03_P02通路Ａ刀後３ポリゴンデモ２終了'

	eval($w:p_story = d:ST:P074_03_P02通路Ａ刀後３ポリゴンデモ２終了)



	@rt_P075_01_R01オタコン無事１無線機デモ１



//	chara delay ディレイ \

//		-time 1 \ 

//		-exec{

//	ゲーム(w43a)には戻らずにそのまま次のステージです

//		}

}





// シネマスクリーン

proc シネマスクリーンセット {

	chara シネマスクリーン シネマ \

		-top d:CINEMA_BELT_UPPER \

		-bottom d:CINEMA_BELT_LOWER \

		-ftime 60	//デフォルト値（ゼロは駄目）

	mesg シネマスクリーン シネマ フェードアウト 1

}





		proc デモ再生_P073_02_p01 {

			chara demo デモ再生 \

				-i t:p073_02_p01 \

				-p null \

				-rename_evm rai_def_mh_mt rai_gbs_raihead_mh_mt \

				-next P073_02_p01終了

		}



		proc デモ再生_P073_04_p02 {

			chara demo デモ再生 \

				-i t:p073_04_p02 \

//				-i t:data_dummy_raiden \

				-p null \

				-rename_evm rai_def_mh_mt rai_gbs_raihead_mh_mt \

				-next P073_04_p02終了

		}



		proc デモ再生_P074_01_p01 {

			chara demo デモ再生 \

				-i t:p074_01_p01 \

				-p null \

				-rename_evm rai_def_mh_mt rai_gbs_raihead_mh_mt \

				-next P074_01_p01終了

		}

	proc デモ再生_P074_03_p02 {

			chara demo デモ再生 \

				-i t:p074_03_p02 \

				-p null \

				-rename_evm rai_def_mh_mt rai_gbs_raihead_mh_mt \

				-next P074_03_p02終了x

		}



// サウンド

proc サウンドマネージャーセット {

	chara サウンドマネージャー ＳＤマネ -pak -1		// パックをロードしない

}



proc サウンドマネージャー_mesg_1 {

	command セットサウンドコード -c d:SNG_PLAY_06

}



proc サウンドマネージャー_mesg_2 {

	command セットサウンドコード -c d:SNG_FOUTS_S

}





