/*

	a21_bomb.h

	    ＥＦ連絡橋（アナザーミッション用モード別設定ファイル）



	2002/02/04 S.Mukaide

	$Id: a21_bomb.h,v 1.6 2002/07/16 06:19:45 usr03682 Exp $





*/





//------------------------------------------------------------

// 各ミッション別で使用するdefine

//------------------------------------------------------------

#define	MISSION_BOMB	1	// 爆弾解体用プロック起動用







//------------------------------------------------------------

// mode.hで呼び出されるプロック

//------------------------------------------------------------

//------------------------------------------------------------

// chara マップの前に呼ばれるproc

//------------------------------------------------------------

proc 爆弾解体ミッション用マップ定義前設定 {

	@全ミッション共通システム設定 d:VR_COUNT_DOWN

}







//---------------------------------------------------

// chara マップ設定、常駐キャラ設定の後に呼ばれるproc

// ※ command マップ設定をしないと全マップに登録されます。

/* このステージで使用されるマップ名

ＥＦ連絡橋

*/

//---------------------------------------------------

proc 爆弾解体ミッション用マップ定義後設定 {

	// 全マップ共通で使用する基本キャラの設定

	command マップ設定 ＥＦ連絡橋 -set {

		@爆弾解体ミッション用サウンド設定	// データは最初に呼ぶ

		@爆弾解体ミッション用変数設定		// ドアのスイッチなどの変数を設定

		@爆弾解体ミッション用コマンダー設定

		@爆弾解体ミッション用ＢＧＭ設定		// プレイヤー→敵兵→BGMの順で呼ぶ

		@爆弾解体ミッション用ガンサイファー配置

		@爆弾解体ミッション用アイテム設置

	}

}







//------------------------------------------------------------

// クリアしたときの処理

//------------------------------------------------------------

proc 爆弾解体ミッション用クリア時処理 {

	#if d:DEBUG_PRINT 

	print 'clear'

	#endif

}







//------------------------------------------------------------

// サウンドに関する設定

//------------------------------------------------------------

proc 爆弾解体ミッション用サウンド設定 {

	#if d:DEBUG_PRINT 

		print 'sound_set-bomb_misson'

	#endif



	chara サウンドマネージャー ＳＤマネ \

		-pak 0



	//		ＳＥ設定

	@サウンド効果音設定

}



proc 爆弾解体ミッション用ＢＧＭ設定 {

	#if d:DEBUG_PRINT 

		print 'bgm_set-bomb_misson'

	#endif



	chara ＢＧＭマネージャー ＢＧＭマネ \

		-s 0x00000001

	chara ＢＧＭ風音 風音 \

		-s d:BGM_WINDNOISE_WEATHER_FAIN

}







//------------------------------------------------------------

// 変数に関する設定

//------------------------------------------------------------

proc 爆弾解体ミッション用変数設定 {

	#if d:DEBUG_PRINT 

		print 'stage_var_set-bomb_misson'

	#endif



	//------------------------------------------------------------

	// ドアに関する設定

	//------------------------------------------------------------

	eval ($$b:ドアフラグ[0] = d:DOOR_FLAG_OPEN);	// Ｅ脚ドア

	eval ($$b:ドアフラグ[1] = d:DOOR_FLAG_OPEN);	// Ｆ脚ドア

	eval ($$b:ドアフラグ[2]=  d:DOOR_FLAG_OPEN);	// 中央棟ドア

}







//------------------------------------------------------------

// 敵兵に関する設定

//------------------------------------------------------------

proc 爆弾解体ミッション用警備兵セット {

	#if d:DEBUG_PRINT 

		print 'watcher_set-bomb_misson'

	#endif

	//	A_警備兵 $:名前 $:ルート $:ノード $:ステータス $:守備Ｘ $:守備Ｙ $:守備Ｚ $:守備マップ

	chara 警備兵 敵兵:01 \

		-r 1 -n 14 -s d:ENE_STATUS_ACCDNT_REPO \		//	発見後アクシデント報告

		-d 63750,4500,-90250 ＥＦ連絡橋 \

		-i $w:敵潜入視力, $w:敵危険視力, $w:敵回避視力 \

		-l $w:敵標準体力 -h $w:敵標準聴力 -f $w:敵標準気絶 \

		-z 23000		//	双眼鏡装備時の＋視力

}



proc 爆弾解体ミッション用攻撃兵セット {

	#if d:DEBUG_PRINT 

		print 'attacker_set-bomb_misson'

	#endif

	//	A_攻撃兵 $:名前 $:ルート $:ステータス $:装備

	//	A_サポート攻撃兵 $:名前 $:ルート $:ステータス $:装備 $:サポートする敵兵名

}



proc 爆弾解体ミッション用警備兵コマンダー {

	#if d:DEBUG_PRINT

		print 'wccomm_set-bomb_misson'

	#endif



	chara 警備コマンダー wccomm -e { 爆弾解体ミッション用警備兵セット }

}



proc 爆弾解体ミッション用攻撃兵コマンダー {

	#if d:DEBUG_PRINT

		print 'atcomm_set-bomb_misson'

	#endif



	chara 攻撃コマンダー atcomm \

		-e { 爆弾解体ミッション用攻撃兵セット } \

		-wait (60*3) \			/*危険開始時の出動遅らせ時間*/

		-avoidwait (60*5) \		/*回避モードで始まる場合のみ有効*/

		-status 0x01

}



proc 爆弾解体ミッション用コマンダー設定 {

	#if d:DEBUG_PRINT

		print 'commander_set-bomb_misson'

	#endif



	chara コマンダー 敵兵セット \

		-w 爆弾解体ミッション用警備兵コマンダー \

		-r 60000,4500,-90250 ＥＦ連絡橋 \

		-c 60000,4500,-90250 ＥＦ連絡橋 \

		-v [ene_plant_voice:04] \

		-x [ghq_area_alert_voice:w21a] \

		-y [ghq_caution_voice:w21a] \

		-z $i:敵標準麻酔持続 \

		-o $i:敵標準気絶持続 \

		-b $w:敵標準再発生数 \

		-s (d:ENE_STAGE_GPS | d:ENE_STAGE_VR_ANOTHER) \

		-m $w:スタートアラートモード \

		-h $i:標準警戒時間 \		//	警戒時間

		-t $w:サイファー標準再発生数 \	//	$i:サイファー危険モードでの復活数

		-u $w:サイファー標準再発生数 \	//	$i:サイファーそのステージでの復活数

		-l 爆弾解体ミッション用ガンサイファー全滅	//	サイファー全滅時に呼ばれる

}



//------------------------------------------------------------

// サイファーに関する設定

//------------------------------------------------------------

//	"@A_危険発生ガンサイファ"使用時必要。コマンダーに登録する

proc 爆弾解体ミッション用ガンサイファー全滅 {

	#if d:DEBUG_PRINT

		print 'guncypher_destroy-bomb_misson'

	#endif



	eval ($b:a21_サイファー破壊ロード回数[0] = $w:グローバルロード回数)

}



proc 爆弾解体ミッション用ガンサイファー配置 {

	#if d:DEBUG_PRINT

		print 'cypher_set-bomb_misson'

	#endif



	@サイファー再セットチェック $b:a21_サイファー破壊ロード回数[0]

	if ($f:再セットフラグ) {

		//	A_危険再発生ガンサイファ $:名前 $:ルート $:ノード $:潜入視力 $:危険視力 $:警戒視力 $:回避視力 \

		//	$:速度 $:危険速度 $:通常加速力 $:危険加速力 $i:待機ルート $i:中継ルート $i:追跡ルート

		@A_危険再発生ガンサイファ ガンサイファー:01 2 0 8000 16000 8000 8000 \

			15 300 200 275 2 5 8

		@A_危険再発生ガンサイファ ガンサイファー:02 3 0 8000 16000 8000 8000 \

			30 300 200 275 3 6 9

		@A_危険再発生ガンサイファ ガンサイファー:03 4 0 8000 16000 8000 8000 \

			60 300 200 275 4 7 10



		//	最初から巡回させる

		mesg サイファ ガンサイファー:01 呼び寄せルートワープ 8 0

		mesg サイファ ガンサイファー:02 呼び寄せルートワープ 9 2

		mesg サイファ ガンサイファー:03 呼び寄せルートワープ 10 0

	}

}



//------------------------------------------------------------

// アイテムに関する設定

//------------------------------------------------------------

proc 爆弾解体ミッション用アイテム取得時番号設定 $:ボックス名 {

	#if d:DEBUG_PRINT

		print 'item_no_set-bomb_misson'

	#endif



	if($:ボックス名 == ＡＫ弾:01) {

		eval($b:w21a_取得ロード回数[0] = $w:グローバルロード回数);

	} else if($:ボックス名 == チャフ:01) {

		eval($b:w21a_取得ロード回数[1] = $w:グローバルロード回数);

	}

}

proc 爆弾解体ミッション用アイテム設置 {

	#if d:DEBUG_PRINT

		print 'w21_item_set-bomb_misson'

	#endif



		@アイテム再セットチェック $b:w21a_取得ロード回数[0]

		if ($f:再セットフラグ) {

			@弾薬_ＡＫＳ_初期設置 ＡＫ弾:01 23000 -1500 -61250 0		//	Ｂ１東側

		}



		//	夕方のみ

		#if d:W21B

			@アイテム再セットチェック $b:w21a_取得ロード回数[1]

			if ($f:再セットフラグ) {

				@チャフ_初期設置 チャフ:01 58250 0 -45250 0				//	Ｆ脚通路

			}

		#endif



}





