/*

	a02a_bomb.h

		エンジンルーム（爆弾解体ミッション用）

	2002/02/01 S.Kaneyoshi

	$Id: a02a_bomb.h,v 1.29 2002/10/02 09:04:16 usr04249 Exp $

*/



#define MISSION_BOMB	1	// 爆弾解体ミッション用プロック起動用



/*************************************************************************************/

// chara マップの前に呼ばれるproc

/*************************************************************************************/

	proc 爆弾解体ミッション用マップ定義前設定 {

		/*

		if ( $f:爆弾解体ミッションＶＲウィンドウ表示フラグ == 0 ) {

			// 他のステージからロードしてきたときは前のステージのタイムを引き継ぐ

			$$i:ライデンタイム 				= $i:爆弾解体タイマー残り時間;

			$$i:スネークタイム 				= $i:爆弾解体タイマー残り時間;

			$$i:プリスキンタイム 			= $i:爆弾解体タイマー残り時間;

			$$i:タキシードスネークタイム 	= $i:爆弾解体タイマー残り時間;

			$$i:刀ライデンタイム 			= $i:爆弾解体タイマー残り時間;

			$$i:前作スネークタイム			= $i:爆弾解体タイマー残り時間;

		}

		*/



		// ウィンドウが表示される場合はみねうちフラグとキルカウント、発見回数を初期化する

		command セットＶＲキルカウント 0

		command セットＶＲ発見回数 0

		@爆弾解体用キャラ別標準装備設定



		// 共通システムの起動 (爆弾解体ミッションは共通で処理するようになったので引数は見なくなりました)

		@全ミッション共通システム設定 d:VR_GOAL_FREE



		// ウィンドウの表示（最初のロードのときのみ）

		if ( $f:爆弾解体ミッションＶＲウィンドウ表示フラグ == 1 ) {

			@爆弾解体ミッション用ＶＲウィンドウ設定

		} else {

			// プレイヤーが動けるようになったらタイマーをスタートさせる処理

			@ロード時ＶＲタイマー処理

		}



		$$i:ＶＲクリアフラグ = d:VRCLR_NO_RETRY;	// プログラムでＲＥＴＲＹをかけない



//	テイルズＥ以外では

#ifndef d:E_TALES

		@ＶＲクリア設定 p:load_alt_bomb_a41a p:load_alt_bomb_a02a

//	テイルズＥのときは

#else

		@テイルズＥ用ＶＲクリア設定１

#endif



		if ( $s:選択プレイヤー == 前作スネーク ) {

			// 前作スネークのときのみレーダーをオフにする

			// レーダーの設定

			command メニュー設定 -node_access off

		}



		// 敵兵配置はスネークテイルズを使用

		command セットルートオフセット d:SCN:スネークテイルズ -c d:SCN:通常

	}





/*************************************************************************************/

// chara マップの後に呼ばれるproc

/*************************************************************************************/

	proc 爆弾解体ミッション用マップ定義後設定 {



		// プレイヤー起動後、ウインドウを表示するときはプレイヤーを消す

		if ( $f:爆弾解体ミッションＶＲウィンドウ表示フラグ == 1 ) {

			command プレイヤー消去キャラ

			// フラグはすぐに寝かす

			$f:爆弾解体ミッションＶＲウィンドウ表示フラグ = 0

		}



		// 全マップ共通基本キャラ設定

		command マップ設定	右舷小部屋 \

							エンジンルーム \

							左舷小部屋 \

							右舷居住区Ｂ１ \

							左舷居住区Ｂ１ \

		-set {

			//@各ミッション用ゴール表示 9362 -5000 -22000

			@爆弾解体ミッション用サウンド設定

			@爆弾解体ミッション用変数設定

			@爆弾解体ミッション用コマンダー設定

			@爆弾解体ミッション用敵兵ルート変更

			@爆弾解体ミッション用ＢＧＭ設定			// プレイヤー→敵兵→BGMの順で呼ぶ

			@爆弾解体ミッション用アイテムセット





			@爆弾解体ミッション用解体Ｃ４設置

		}



		// 各マップで使用するキャラの設定(アイテム等)

		command マップ設定 右舷小部屋 -set {



		}

	}



	proc 爆弾解体ミッション用サウンド設定 {

		#if d:DEBUG_PRINT

			print 'sound_set-bomb_misson'

		#endif



		@サウンドデータ常駐読み替え設定

		chara サウンドマネージャー ＳＤマネ -pak 0

		@サウンド効果音設定



		trap ev201 d:PLAYER \

			-mask ？ \

			-exec {

				if( $3 == 入る ) {

					command ＳＥセットモード -s d:se_code:SD_A_ENGINESE -p 0 0 0 -m 1

				} else {

					command セットサウンドコード -c d:SE_JOUCHUU_OFF

				}

			}



	}



	proc 爆弾解体ミッション用ＢＧＭ設定 {

		#if d:DEBUG_PRINT

			print 'bgm_set-bomb_misson'

		#endif

		//chara ＢＧＭマネージャー ＢＧＭマネ



		chara ＢＧＭマネージャー ＢＧＭ -s 0x00000001



		chara ＢＧＭフェーダー エンジン音低 \

			-t /*0x07*/23 \

			-a -500,-12000,-7000 3000,5000,30000 w02a



		chara ＢＧＭフェーダー エンジン音高 \

			-t /*0x08*/24 \

			-a -500,-8000,-7000 3000,5000,30000 w02a





		command システムコールバック -active_map_change マップ変更コールバック





	}



	proc 爆弾解体ミッション用変数設定 {

		#if d:DEBUG_PRINT

			print 'stage_var_set-bomb_misson'

		#endif

		//------------------------------------------------------------

		// ドアに関する設定

		//		DOOR_FLAG_CLOSE			0		// 絶対開かない

		//		DOOR_FLAG_OPEN			1		// 絶対開く

		//		DOOR_FLAG_ENEMY_ONLY	2		// 敵兵のみ開く

		//		DOOR_FLAG_CLOSE_LEVEL	3		// カードレベルが足りなくて開かない

		//		DOOR_FLAG_OPEN_LEVEL	4		// カード持っているので開く

		//------------------------------------------------------------



		$$b:ドアフラグ[0] = 2;

		$$b:ドアフラグ[1] = 2;

		$$b:ドアフラグ[2] = 2;

	}



/*************************************************************************************/

// ＶＲウィンドウの設定と表示

/*************************************************************************************/

proc 爆弾解体ミッション用ＶＲウィンドウ設定 {

	#if d:DEBUG_PRINT

		print 'vr_window_set'

	#endif



	@爆弾解体ミッションＶＲウィンドウ設定 p:爆弾解体ミッション用ステージ開始時処理





	// ＶＲウィンドウを表示する

	mesg ＶＲウィンドウ ＶＲウィンドウ君 開く



	// スタート時とクリア時に使用するカットインカメラ

	chara カメラ カットインカメラ		-c 0 -l 0 -p  0



	// スタート時のカメラ(必要な場合)

	chara カメラ設定 カットインカメラ \

		-c 1 \

		-p 9300,-2905,-10750 -t 8750,-3731,-14250 \

		-r 151,2048,0 -f 3596 \

		-a 200 \

		-i 0 -1 0 0 \

		-s 1

}





/*************************************************************************************/

// ステージ開始時処理

/*************************************************************************************/

proc 爆弾解体ミッション用ステージ開始時処理 {

	#if d:DEBUG_PRINT

		print 'game_start!!!!!'

	#endif



	// プレイヤーやパッドの制御等を行う a_stdproc.hで定義

	@全ミッション共通ステージ開始時処理





	// カメラワークスタート(必要な場合)

	// 全体図

	chara カメラ設定 カットインカメラ \

		-c 1 \

		-p 9300,-2905,-10750 -t 8750,-3731,-14250 \

		-r 151,2048,0 -f 3596 \

		-a 200 \

		-i 4 4 d:START_CAMERA_CHANGE_TIME d:START_CAMERA_CHANGE_TIME \

		-s 1



	chara delay ディレイ \

		-time d:START_CAMERA_CHANGE_TIME \

		-exec {

			chara カメラ設定 カットインカメラ -s -1

		}



}



/*************************************************************************************/

// クリア時に呼ばれるプロック

/*************************************************************************************/

	proc 爆弾解体ミッション用クリア時処理 {

		#if d:DEBUG_PRINT

			print 'game clear'

		#endif

		@各ミッション共通モーションなしクリア処理



/*

		chara カメラ設定 カットインカメラ \

			-c 1 \

			-p -2209,-13877,-60193 -t -2480,-14860,-57681 \

			-r 242,4026,0 -f 2711 \

			-a 200 \

			-i 2 2 0 0 \

			-s 1

*/

	}



/*************************************************************************************/

// 敵兵の設定

/*************************************************************************************/

#define ET_DEF_X_1		9500

#define ET_DEF_Y_1		-5000

#define ET_DEF_Z_1		-22000



#define ET_DEF_X_2		7000

#define ET_DEF_Y_2		-5000

#define ET_DEF_Z_2		-18000



#define ET_DEF_X_3		7000

#define ET_DEF_Y_3		-13000

#define ET_DEF_Z_3		-2000



#define ET_DEF_X_4		-2000

#define ET_DEF_Y_4		-9000

#define ET_DEF_Z_4		-1500



#define ET_DEF_X_5		-7000

#define ET_DEF_Y_5		-5000

#define ET_DEF_Z_5		-15000





	proc 爆弾解体ミッション用警備兵セット {

		#if d:DEBUG_PRINT

			print 'watcher_set-bomb_misson'

		#endif



		@A_警備兵 敵兵:01 \

			1 \		// ルート

			0 \		// ノード

			d:ENE_STATUS_GUNLIGHT \

			d:ET_DEF_X_1 d:ET_DEF_Y_1 d:ET_DEF_Z_1 \

			右舷小部屋

		/*

		@A_警備兵 敵兵:02 \

			2 \		// ルート

			0 \		// ノード

			d:ENE_STATUS_GUNLIGHT \

			d:ET_DEF_X_2 d:ET_DEF_Y_2 d:ET_DEF_Z_2 \

			エンジンルーム

		*/

		@A_警備兵 敵兵:03 \

			3 \		// ルート

			0 \		// ノード

			d:ENE_STATUS_GUNLIGHT \

			d:ET_DEF_X_3 d:ET_DEF_Y_3 d:ET_DEF_Z_3 \

			エンジンルーム



		@A_警備兵 敵兵:04 \

			4 \		// ルート

			0 \		// ノード

			d:ENE_STATUS_GUNLIGHT \

			d:ET_DEF_X_4 d:ET_DEF_Y_4 d:ET_DEF_Z_4 \

			エンジンルーム



		@A_警備兵 敵兵:05 \

			5 \		// ルート

			0 \		// ノード

			d:ENE_STATUS_GUNLIGHT \

			d:ET_DEF_X_5 d:ET_DEF_Y_5 d:ET_DEF_Z_5 \

			エンジンルーム

	}



	proc 爆弾解体ミッション用攻撃兵セット {

		#if d:DEBUG_PRINT

			print 'attacker_set-bomb_misson'

		#endif



		@A_探索ルート付き攻撃兵 敵兵:61 \

			13 \

			9 \

			d:ENE_STATUS_GUNLIGHT \

			d:ENE_EQUIP_TYPE_LIGHT_SHIELD

		@A_探索ルート付き攻撃兵 敵兵:62 \

			14 \

			10 \

			d:ENE_STATUS_GUNLIGHT \

			d:ENE_EQUIP_TYPE_LIGHT_SHIELD

		@A_探索ルート付き攻撃兵 敵兵:63 \

			15 \

			11 \

			d:ENE_STATUS_GUNLIGHT \

			d:ENE_EQUIP_TYPE_LIGHT_SHIELD

		@A_探索ルート付き攻撃兵 敵兵:64 \

			16 \

			12 \

			d:ENE_STATUS_GUNLIGHT \

			d:ENE_EQUIP_TYPE_LIGHT_SHIELD

	}



	proc 爆弾解体ミッション用警備兵コマンダー {

		#if d:DEBUG_PRINT

			print 'wccomm_set-bomb_misson'

		#endif



		chara 警備コマンダー wccomm \

			-e { 爆弾解体ミッション用警備兵セット }

	}



	proc 爆弾解体ミッション用攻撃兵コマンダー {

		#if d:DEBUG_PRINT

			print 'atcomm_set-bomb_misson'

		#endif



		chara 攻撃コマンダー atcomm \

			//-wait		180 \

			//-avoidwait	300 \

			-e { 爆弾解体ミッション用攻撃兵セット }

	}



	proc 爆弾解体ミッション用コマンダー設定 {

		#if d:DEBUG_PRINT

			print 'commander_set-bomb_misson'

		#endif





		if( $s:登場ポイント == 大佐デモから ) {

			$w:スタートアラートモード = d:ALERT_MODE_SENNYU;

		}



		chara コマンダー 敵兵セット \

			-w 爆弾解体ミッション用警備兵コマンダー \

			-a 爆弾解体ミッション用攻撃兵コマンダー \

			-s (d:ENE_STAGE_VR_ANOTHER) \

			-m $w:スタートアラートモード \

			-r	12500,0,-15500 右舷居住区Ｂ１ \

			-c 12500,0,-15500 右舷居住区Ｂ１ \

			-p	0,-1,-1,右舷Ｂ３クリアリング初期設定 \

				1,-1,-1,左舷Ｂ３クリアリング初期設定 \

				2,-1,-1,左舷小部屋クリアリング初期設定 \

				3,-1,-1,右舷小部屋クリアリング初期設定 \

				-2,-2,-2,クリアリングカメラＯＦＦ \

			-x [ghq_area_alert_voice:w02a] \

			-y [ghq_caution_voice:a02a] \

			-v [ene_tank_voice:06] \

			-b $w:敵標準再発生数 \

			-z $i:敵標準麻酔持続 \

			-h $i:標準警戒時間 \

			-o $i:敵標準気絶持続



	}



	///////////////////////////////////////////////////////////

	// スネークが左舷小部屋に入った時のアタッカーの初期位置変更

	proc 爆弾解体ミッション用敵兵ルート変更 {

		trap en402 d:PLAYER \

			-mask 入る \

			-exec {

				mesg アタッカー 敵兵:61 ルート変更 (1-1)

				mesg アタッカー 敵兵:62 ルート変更 (1-1)

				mesg アタッカー 敵兵:63 ルート変更 (1-1)

				mesg アタッカー 敵兵:64 ルート変更 (1-1)

			}

	}



/*************************************************************************************/

// アイテム関連

/*************************************************************************************/



	proc 爆弾解体ミッション用アイテム取得時番号設定 $:ボックス名 {

		#if d:DEBUG_PRINT

			print 'item_no_set'

		#endif



		if ($:ボックス名 == ＵＳＰ弾１) {

			eval($b:w02a_取得ロード回数[0] = $w:グローバルロード回数);

		}



		#if d:DEBUG_PRINT

			print $:ボックス名

			print $w:グローバルロード回数

		#endif

	}



	proc 爆弾解体ミッション用アイテムセット {

		/*

		@アイテム再セットチェック $b:w02a_取得ロード回数[0]

		if ($f:再セットフラグ) {

			@弾薬_ＵＳＰ_初期設置 ＵＳＰ弾１ 16224 -4000 -22618 0

		}

		*/

	}



/*************************************************************************************/

// 解体Ｃ４設置

/*************************************************************************************/



	proc 爆弾解体ミッション用解体Ｃ４設置 {

		#if d:DEBUG_PRINT

			print 'a02a_bomb_set-bomb_misson'

		#endif



		switch ( $s:選択プレイヤー) {

			case ( ライデン ) {

				@ライデン用解体Ｃ４設置

			}

			case ( スネーク ) {

				@スネーク用解体Ｃ４設置

			}

			case ( プリスキン ) {

				@プリスキン用解体Ｃ４設置

			}

			case ( タキシードスネーク ) {

				@タキシードスネーク用解体Ｃ４設置

			}

			case ( 刀ライデン ) {

				@刀ライデン用解体Ｃ４設置

			}

			case ( 前作スネーク ) {

				@前作スネーク用解体Ｃ４設置

			}

		}

	}



/*************************************************************************************/

// 爆弾を解体したときに呼ばれるプロック

/*************************************************************************************/

	proc A_各ステージ別爆弾解体時処理 $:p_解体爆弾名 {

		#if d:DEBUG_PRINT

			print 'a14a_bomb_disposal $:p_解体爆弾名='$:p_解体爆弾名

		#endif



		switch ( $s:選択プレイヤー) {

			case ( ライデン ) {

				@ライデン用爆弾解体時プロック $:p_解体爆弾名

			}

			case ( スネーク ) {

				@スネーク用爆弾解体時プロック $:p_解体爆弾名

			}

			case ( プリスキン ) {

				@プリスキン用爆弾解体時プロック $:p_解体爆弾名

			}

			case ( タキシードスネーク ) {

				@タキシードスネーク用爆弾解体時プロック $:p_解体爆弾名

			}

			case ( 刀ライデン ) {

				@刀ライデン用爆弾解体時プロック $:p_解体爆弾名

			}

			case ( 前作スネーク ) {

				@前作スネーク用爆弾解体時プロック $:p_解体爆弾名

			}

		}



		/*

		// このエリアは全キャラ爆弾がひとつなので、解体したらマップの爆弾マークを取る

		command ＶＲ全体マップ表示３Ｄ＿爆弾解除 -b d:F_PLANT_B

		$i:A_全体マップ爆弾設置ステージ = ( $i:A_全体マップ爆弾設置ステージ & ~(d:F_PLANT_B) );

		*/

	}



/*************************************************************************************/

// キャラ別の爆弾プロック ライデン

/*************************************************************************************/



	proc ライデン用解体Ｃ４設置 {

		@A_解体Ｃ４設置 解体Ｃ４:01 12250 (-2800+200) -25000 0 0 0 \

			d:BOMB_A \			// タイプ

			1 \					// フラグ番号

			d:C4FLAG_NORMAL \	// フラグ

			bm001 \

			もやもや:01



		@A_解体Ｃ４設置 解体Ｃ４:02 -3250,-13000,-500 3072 0 0 \

			d:BOMB_A \			// タイプ

			2 \					// フラグ番号

			d:C4FLAG_NORMAL \	// フラグ

			bm002 \

			もやもや:02

	}



	proc ライデン用爆弾解体時プロック $:p_解体爆弾名 {

		switch ( $:p_解体爆弾名 ) {

			case ( 解体Ｃ４:01 ) {

				$b:A_爆弾解体終了状態フラグ[1] = 1;

				mesg 爆弾検知領域 もやもや:01 消去 d:BOMB_RADAR_OFF_TIME

			}

			case ( 解体Ｃ４:02 ) {

				$b:A_爆弾解体終了状態フラグ[2] = 1;

				mesg 爆弾検知領域 もやもや:02 消去 d:BOMB_RADAR_OFF_TIME

			}

		}

	}



/*************************************************************************************/

// キャラ別の爆弾プロック スネーク

/*************************************************************************************/



	proc スネーク用解体Ｃ４設置 {

		/*

		// エンジン右横

		@A_解体Ｃ４設置 解体Ｃ４:11 3718 -7816 -12000 (-255) 1024 0 \

			d:BOMB_A \			// タイプ

			1 \					// フラグ番号

			d:C4FLAG_NORMAL \	// フラグ

			bm011 \

			もやもや:11

		*/

		@A_解体Ｃ４設置 解体Ｃ４:11 5975,-8800,-11500 0 1024 0 \

			d:BOMB_A \			// タイプ

			1 \					// フラグ番号

			d:C4FLAG_NORMAL \	// フラグ

			bm011 \

			もやもや:11



		@A_解体Ｃ４設置 解体Ｃ４:12 -17625,-4000,-31375 0 1024 0 \

			d:BOMB_A \			// タイプ

			2 \					// フラグ番号

			d:C4FLAG_NORMAL \	// フラグ

			bm012 \

			もやもや:12

	}



	proc スネーク用爆弾解体時プロック $:p_解体爆弾名 {

		switch ( $:p_解体爆弾名 ) {

			case ( 解体Ｃ４:11 ) {

				$b:A_爆弾解体終了状態フラグ[1] = 1;

				mesg 爆弾検知領域 もやもや:11 消去 d:BOMB_RADAR_OFF_TIME

			}

			case ( 解体Ｃ４:12 ) {

				$b:A_爆弾解体終了状態フラグ[2] = 1;

				mesg 爆弾検知領域 もやもや:12 消去 d:BOMB_RADAR_OFF_TIME

			}

		}

	}



/*************************************************************************************/

// キャラ別の爆弾プロック プリスキン

/*************************************************************************************/



	proc プリスキン用解体Ｃ４設置 {

		@A_解体Ｃ４設置 解体Ｃ４:21 18250,-2500,-24000 3072 0 0 \

			d:BOMB_B \			// タイプ

			1 \					// フラグ番号

			d:C4FLAG_NORMAL \	// フラグ

			bm021 \

			もやもや無し



		@A_解体Ｃ４設置 解体Ｃ４:22 -6200,-7100,-16000 0 2048 0 \

			d:BOMB_B \			// タイプ

			2 \					// フラグ番号

			d:C4FLAG_NORMAL \	// フラグ

			bm022 \

			もやもや無し



	}



	proc プリスキン用爆弾解体時プロック $:p_解体爆弾名 {

		switch ( $:p_解体爆弾名 ) {

			case ( 解体Ｃ４:21 ) {

				$b:A_爆弾解体終了状態フラグ[1] = 1;

				command トラップ切り替え -trap bm021 -switch 0

			}

			case ( 解体Ｃ４:22 ) {

				$b:A_爆弾解体終了状態フラグ[2] = 1;

				command トラップ切り替え -trap bm022 -switch 0

			}

		}

	}



/*************************************************************************************/

// キャラ別の爆弾プロック タキシードスネーク

/*************************************************************************************/



	proc タキシードスネーク用解体Ｃ４設置 {

		@A_解体Ｃ４設置 解体Ｃ４:31 6000,-14000,-16750 0 3072 0 \

			d:BOMB_B \			// タイプ

			1 \					// フラグ番号

			d:C4FLAG_NORMAL \	// フラグ

			bm031 \

			もやもや無し



		@A_解体Ｃ４設置 解体Ｃ４:32 -11000,-11000,-3400 0 3072 0 \

			d:BOMB_B \			// タイプ

			2 \					// フラグ番号

			d:C4FLAG_NORMAL \	// フラグ

			bm032 \

			もやもや無し



	}



	proc タキシードスネーク用爆弾解体時プロック $:p_解体爆弾名 {

		switch ( $:p_解体爆弾名 ) {

			case ( 解体Ｃ４:31 ) {

				$b:A_爆弾解体終了状態フラグ[1] = 1;

				command トラップ切り替え -trap bm031 -switch 0

			}

			case ( 解体Ｃ４:32 ) {

				$b:A_爆弾解体終了状態フラグ[2] = 1;

				command トラップ切り替え -trap bm032 -switch 0

			}

		}

	}



/*************************************************************************************/

// キャラ別の爆弾プロック 刀ライデン

/*************************************************************************************/



	proc 刀ライデン用解体Ｃ４設置 {

		@A_解体Ｃ４設置 解体Ｃ４:41 5000,-12600,-300 0 3072 0 \

			d:BOMB_B \			// タイプ

			1 \					// フラグ番号

			d:C4FLAG_NORMAL \	// フラグ

			bm041 \

			もやもや無し



		@A_解体Ｃ４設置 解体Ｃ４:42 -12500,-11100,3650 0 2048 0 \

			d:BOMB_A \			// タイプ

			2 \					// フラグ番号

			d:C4FLAG_NORMAL \	// フラグ

			bm042 \

			もやもや:42



	}



	proc 刀ライデン用爆弾解体時プロック $:p_解体爆弾名 {

		switch ( $:p_解体爆弾名 ) {

			case ( 解体Ｃ４:41 ) {

				$b:A_爆弾解体終了状態フラグ[1] = 1;

				command トラップ切り替え -trap bm041 -switch 0

			}

			case ( 解体Ｃ４:42 ) {

				$b:A_爆弾解体終了状態フラグ[2] = 1;

				mesg 爆弾検知領域 もやもや:42 消去 d:BOMB_RADAR_OFF_TIME

			}

		}

	}



/*************************************************************************************/

// キャラ別の爆弾プロック 前作スネーク

/*************************************************************************************/



	proc 前作スネーク用解体Ｃ４設置 {



		@A_解体Ｃ４設置 解体Ｃ４:51 600,-12000,-17000 3072 0 0 \

			d:BOMB_B \			// タイプ

			1 \					// フラグ番号

			d:C4FLAG_NORMAL \	// フラグ

			bm051 \

			もやもや無し



		@A_解体Ｃ４設置 解体Ｃ４:52 100,-9000,-18550 3072 0 0 \

			d:BOMB_A \			// タイプ

			2 \					// フラグ番号

			d:C4FLAG_NORMAL \	// フラグ

			bm052 \

			もやもや:52



		@A_解体Ｃ４設置 解体Ｃ４:53 -11250 -7250 -8450 1024 0 0 \

			d:BOMB_B \			// タイプ

			3 \					// フラグ番号

			d:C4FLAG_NORMAL \	// フラグ

			bm053 \

			もやもや無し



	}



	proc 前作スネーク用爆弾解体時プロック $:p_解体爆弾名 {

		switch ( $:p_解体爆弾名 ) {

			case ( 解体Ｃ４:51 ) {

				$b:A_爆弾解体終了状態フラグ[1] = 1;

				command トラップ切り替え -trap bm051 -switch 0

			}

			case ( 解体Ｃ４:52 ) {

				$b:A_爆弾解体終了状態フラグ[2] = 1;

				mesg 爆弾検知領域 もやもや:52 消去 d:BOMB_RADAR_OFF_TIME

			}

			case ( 解体Ｃ４:53 ) {

				$b:A_爆弾解体終了状態フラグ[3] = 1;

				command トラップ切り替え -trap bm053 -switch 0

			}

		}

	}



