/*

	polydemo_w28a.gcl                     

	    L脚デモ用ヘッダ



	2000/11/30 Y.Matsuhana         

	$Id: polydemo_w28a.h,v 1.19 2001/09/07 09:03:04 usr03635 Exp $                      



*/



/*

注意！　以下のevalは、stdch.hとdemo_stdch.h中の2Dレイアウトドライバ 

の二重呼びを回避するためのものです。各"polydemo_***.h" のこの位置、

include の前に必ずおくこと！！

*/

/* 絶対ここ！　場所も変えない！ */

eval($s:d_num = co_game_demo_stage)

/* 以上！ */



// includes

// ------------------------------------

#include "5sec_bfr_demo.h"

#include "demo_stdch.h"

#include "demo_vardef.h"

#include "sea_surface.h"

#include "p_force_cdc.ch"



#if d:PLANT_DEMO_ALL_SKIP

	#define		DEMO_SKIP_ENABLE 1

#else

	#define		DEMO_SKIP_ENABLE 0

#endif





//###################################################################################

//								ストーリーフラグ & デモ再生

//###################################################################################

command マップ設定 Ｌ脚 -set {

	// デモ環境かどうか。

	#if d:MGS2_DEMO

		// 不要プログラムの起動阻害

		eval($s:d_num = P036_04_p03)

		chara デモアクトデバッグ demodebug  -i t:p065_01_p01 -d 'p065_01_p01' -l   \

			-p  dummy_proc

	#else

	// ゲームＧＣＬと共用で入ってくる部分なので、ここも == で条件を見る。

	if($w:p_story == d:ST:P065_01_P01エマＬ脚１ポリゴンデモ１開始) {

		print'd:ST:P065_01_P01エマＬ脚１ポリゴンデモ１開始'

		/* Ｌ脚ハッチから４０メートル下の海面を見下ろす */

		// デモ特有の変数代入

		eval($s:d_num = P065_01_p01)

		// polydemo_**.h の最初のデモの時には必ず呼ぶこと。レーダー明示的にオフさせる。

		@デモではレーダー不要



		// ナイトビジョンと赤外線ゴーグルは海面キラキラを消してしまうので、

		// 装備していたらはずしてしまう。

		if ( ($w:アイテム == d:アイテム:暗視ゴーグル) || \

			 ($w:アイテム == d:アイテム:サーマルゴーグル) ) {

			eval($w:アイテム = d:アイテム:素手);

		}



		@デモモデル差し替え処理

		@デモ再生_P065_01_p01

	} else if(d:ST:P065_01_P01エマＬ脚１ポリゴンデモ１終了 <= $w:p_story && \

				$w:p_story < d:ST:P065_02_R01エマＬ脚２無線機デモ１開始) {

		print'd:ST:P065_02_R01エマＬ脚２無線機デモ１開始'

		eval($w:p_story = d:ST:P065_02_R01エマＬ脚２無線機デモ１開始)

		/* エマ体内通信　高いところはこわい */

		@サウンドマネージャー_mesg_1

		// デモ特有の変数代入

		eval($s:d_num = P065_02_r01)

		@rt_P065_02_R01エマＬ脚２無線機デモ１

	} else {

		// デモ以外の場合こちらを通る

		@ゲームステージへ戻る

	}

	#endif

	// デモ仕様のセット

	if($s:d_num != not_demo){

		// 共通して使用するもの

		chara デモキャンセルチェック デモキャンセル \

			-p demo_cancel

		// 無線ではシネマスクリーン起動しない

		if($s:d_num != P065_02_r01){

			@シネマスクリーンセット

		}

		@demo_Ｌ脚天井設置

		@プラントステージでのフォグセット 夕 0

	}

} // < 「command マップ設定 Ｌ脚」 の閉じカッコ





// 初期マップ表示

// ゲームgclの方で実施。





// 各proc設定

//-------------------------------------------------------------------------------------

//###################################################################################

//									デモのみ仕様各種

//###################################################################################

// ダミープロック

proc dummy_proc {}



// デモキャンセル

proc demo_cancel {

	command StreamStopAll

}



// リスタート

proc restart_proc {

	restart

}



// デモ終了時プロック

proc P065_01_p01終了 {

	@デモ終了時シネマスクリーンオフ

	mesg デモキャンセルチェック デモキャンセル kill

	eval($w:p_story = d:ST:P065_01_P01エマＬ脚１ポリゴンデモ１終了)

	print '$w:p_story = d:ST:P065_01_P01エマＬ脚１ポリゴンデモ１終了'



	chara delay ディレイ -time 1 \ 

		-exec{

			if ( $w:アイテム == d:アイテム:ゴル兵制服 ) {

				load "w28a" -r 'r_plt0' ;

			} else {

				restart ;

			}

		}

}







// シネマスクリーン

proc シネマスクリーンセット {

	chara シネマスクリーン シネマ \

		-top d:CINEMA_BELT_UPPER \

		-bottom d:CINEMA_BELT_LOWER \

		-ftime 60	//デフォルト値（ゼロは駄目）

	mesg シネマスクリーン シネマ フェードアウト 1

}



	// ドア＆マップ切り替え関係

	// ------------------------------------

	proc demo_ドア設置 {

		chara プットオブジェ 北側ドア \

			-m d:DOOR_NAME_LOAD \

			-r 0,0,0 \

			-p 48000,0,-223625 \

			-s 100,100,100 \

			-l d:LT2_NAME



		// 南側は水密ドア

		chara プットオブジェ 南側ドア \

			-m w28a_sdr_r \ // ハンドル込みのモデルを用意する必要有り。

			-r 0,2048,0 \

			-p 53125,0,-206000 \

			-s 100,100,100 \

			-l d:LT2_NAME

	}



	// フォグ

	// ------------------------------------

	// 直接、sea_surface.hのプロックを↑に記述。



	// 海面セット

	// ------------------------------------

	// 直接、sea_surface.hのプロックを↑に記述。



	// エフェクト関係

	// -----------------------------------

	proc demo_エフェクト設定 {

//			chara ブラー ブラー

//			chara Ｚフォーカス管理 Z_manager

//			mesg Ｚフォーカス管理 Z_manager パラメータ 5000 30

			chara ＯＦＦ制御 off_man

			mesg ＯＦＦ制御 off_man ボディシャドウＯＦＦ

	}



// 各マップ別設定

// ------------------------------------

// Ｌ脚

	// ステージ本体

	proc demo_ステージモデル本体セット {

		chara プットオブジェ ステージモデル \

			-m d:KMS_NAME0 \

			-r 0,0,0 \

			-p 0,0,0 \

			-s 100,100,100 \

			-l d:LT2_NAME

	}



	// 天井設置

	// ------------------------------------

	proc demo_Ｌ脚天井設置 {

		chara プットオブジェ Ｌ脚天井設置 \

			-m d:CIEL_NAME \

			-r 0,0,0 \

			-p 0,0,0 \

			-s 100,100,100 \

			-l d:LT2_NAME

	}



	// ハッチ設定

	// ------------------------------------

	proc demo_ハッチ設定 {

		chara プットオブジェ w28aハッチ \

			-m d:HATCH_NAME \

			-r 0,3072,0 \

			-p 51000,0,-205500 \

			-s 100,100,100 \

			-l d:LT2_NAME

	}



	// 再生本体

	// ------------------------------------

	proc デモ再生_P065_01_p01 {

		print 'p065_01_p01 デモ再生開始'

		chara demo デモ再生 \

			-i t:p065_01_p01 \

			-p dummy_proc \

			-rename_evm rai_def_mh_mt rai_gbs_raihead_mh_mt \

			-next P065_01_p01終了

	}



// サウンド

proc サウンドマネージャーセット {

	chara サウンドマネージャー ＳＤマネ -pak -1		// パックをロードしない

}



proc サウンドマネージャー_mesg_1 {

	chara サウンドマネージャー ＳＤマネ -pak -1			// 牧村依頼により削除(2001.8.20)

	command セットサウンドコード -c d:SNG_PLAY_05

}

